概述

  使用程序化交易，使用者仅仅具备编写能力是不够的，当排查方向指向策略内部逻辑时，使用者除了凭借经验以外，还应该灵活掌握调试技巧，才能够更加顺畅的解决量化交易问题。调试涵盖以下四种方法：

图表调试

基于K线图光标定位调试图表策略

监控输出

输出策略执行时全部变量的结果

调试函数

输出策略执行时指定变量的结果

调试工具

可调试控制语句内部执行过程

- name: 图表调试
  desc: 基于K线图光标定位调试图表策略
  bgColor: '#DFEEE7'
  textColor: '#242A38'
- name: 监控输出
  desc: 输出策略执行时全部变量的结果
  bgColor: '#F0DFB1'
  textColor: '#242A38'
- name: 调试函数
  desc: 输出策略执行时指定变量的结果
  bgColor: '#CBEAFA'
  textColor: '#242A38'
- name: 调试工具
  desc: 可调试控制语句内部执行过程
  bgColor: '#F6E9E8'
  textColor: '#242A38'

调试技巧

1. 反向定位：根据执行结果或者日志推导相关代码位置，然后自下而上寻找触发条件关联的因子结果。
2. 就近添加：添加中间变量输出时，变量应该写在待排查语句的前后位置，目的是避免因子在其它位置发生修改，产生误导。
3. 由粗到细：排查因子结果由粗到细，例如从组合条件-->各个子条件-->参与条件判断的因子。

图表调试

  图表调试是一种简单高效的调试方法，本质上是通过光标定位到指定K线位置，根据查看到的变量返回结果，判断当前公式的执行逻辑或者状态。

示例：如下图所示中，均线多头金死叉策略，为什么只发生了一次开仓动作，其余金叉条件成立时为什么没有触发动作？

MA1:MA(CLOSE,5);
MA2:MA(CLOSE,20);

if CROSS(MA1,MA2)=1 AND HOLDING=0 then begin
    BUY(1,1,MARKET);    
end

if CROSS(MA2,MA1)=1 AND HOLDING<0 then begin
    SELL(1,1,MARKET);    
end

1. 由图可以判定此现象大概率与交易条件有关，因此在开平仓语句条件处增加变量输出条件结果。相关示例代码见下方代码段；

编程技巧

1. 多使用中间变量，避免出现复杂表达式，既能提高代码可读性，也能有助于进行调试。
2. 若显示的变量会压缩K线图，可以添加LINETHICK0控制符;或者改为:=定义中间变量。
3. 变量输出不支持字符串数据，但是可以通过日志函数等方法打印输出。
4. 单行变量无法全部显示时、或者变量都是通过:=定义不显示时，可以通过键盘
   Shift
   +
   Q
   查看。
   如下图所示：
   

MA1:MA(CLOSE,5);
MA2:MA(CLOSE,20);

{结合K线图显示的结果、以及公式内容，可以判断开仓和平仓都不符预期结果}
if CROSS(MA1,MA2)=1 AND HOLDING=0 then begin
    BUY(1,1,MARKET);    
end

if CROSS(MA2,MA1)=1 AND HOLDING<0 then begin
    SELL(1,1,MARKET);    
end

MA1:MA(CLOSE,5);
MA2:MA(CLOSE,20);

{结合K线图显示的结果、以及公式内容，可以判断开仓和平仓都不符预期结果，因此输出开平仓条件的因子。}
//变量添加采用就近原则。通过:=可以隐藏该变量的结果。
COND1:CROSS(MA1,MA2);   //当前是否金叉
COND2:HOLDING;          //开仓前的仓位 
//判断条件建议结合中间变量处理，可以有效提高代码的可读性。避免组合条件过长。如下行中使用变量cond1代替CROSS(MA1,MA2)=1
if COND1 AND HOLDING=0 then begin
    BUY(1,1,MARKET);    
end

//变量添加采用就近原则。通过:=可以隐藏该变量的结果。
COND3:CROSS(MA2,MA1);   //当前是否死叉
COND4:HOLDING;          //开仓后的仓位 
//错误原因：多头持仓holding>0,此处判断条件为多头持仓<0,造成平仓组合条件恒不成立。
if COND3=1 AND HOLDING<0 then begin
    SELL(1,1,MARKET);    
end

通过调试结果与代码相互验证可知：【失败原因：多头持仓为正数，所以holding<0的条件恒不成立。】

标记1：此位置死叉条件cond3成立、但是此时的holding=0（无持仓），平仓条件不成立。
标记2：此位置金叉条件cond1成立、此时的holding=0,开仓条件成立。
标记3：此位置死叉条件cond3成立、holidng=1（有持仓），但是平仓失败。

监控输出

  监控输出功能将程序化执行过程中使用的策略变量进行记录保存。通过记录关键点的运行结果可以完整的分析策略每次执行过程中的逻辑。此功能对于初学者较为友好，只需增加变量保存指定位置的执行结果即可。

图表程序化启动变量跟踪的步骤如下图所示：

后台程序化启动变量跟踪的步骤如下图所示：

---

技巧与注意事项

1. 不支持字符串变量输出

• 字符串的输出，可以使用日志函数处理。（见下节内容）

//普通变量
MA1:=MA(CLOSE,5);

//字符串变量
品种:STKLABEL;

日志分析：

//默认输出本地计算机时间、K线时间、最新价，三个字段，之后是公式中的变量
//下标[1]处由于是字符串变量，其输出结果被固定数值代替。没有分析意义。
2024-03-28 13:44:04.689 Time:2024.03.28 13:44:00 Close:4256.2 MA1:4257.560 品种:1000000.000 ^[1]
2024-03-28 13:45:03.687 Time:2024.03.28 13:45:00 Close:4251.8 MA1:4254.520 品种:1000000.000

2. 只输出各个变量执行过程中最后的结果

• 若希望跟踪变量在策略中的变化过程，可以在跟踪变量附件增加中间变量。（示例见标签页【变量细节跟踪】）
• 策略中关键条件使用中间变量保存，能够提高监控输出日志的精细度。

开盘价:=open;
探针:=0; 

if close>open*0.99 then begin
    探针:=1;
end

if close>open then begin
    探针:=2;
end

日志分析：

//在第2行变量[探针]初始化为0,然后第4行条件成立，[探针]重新赋值为1；
//最后在第8行条件不成立，不赋值；因此本次执行的最后结果=1
2024-03-28 13:44:04.689 Time:2024.03.28 13:44:00 Close:4260.0 开盘价:4300.000 探针:1.000 ^[1]

//在第2行变量[探针]初始化为0,之后两个判断条件都不成立，均不做赋值处理；因此本次执行的最后结果=0
2024-03-28 13:45:03.687 Time:2024.03.28 13:45:00 Close:4200.0 开盘价:4260.000 探针:0.000^[2]

//在第2行变量[探针]初始化为0,然后第4行条件成立时，[探针]重新赋值为1；
//最后在第8行条件成立，[探针]再次重新赋值为2；因此本次执行的最后结果=2
//两组条件均成立，如何跟踪变量的过程变化？见标签页【变量变化过程跟踪】
2024-03-28 13:46:02.700 Time:2024.03.28 13:46:00 Close:4260.0 开盘价:4250.000 探针:2.000^[3]

开盘价:=open;
探针:=0; 

if close>open*0.99 then begin
    探针:=1;
end
节点1:=探针;  //输出当前代码位置变量[探针]的结果,可以判断[探针]是否发生过修改。

if close>open then begin
    探针:=2;
end
节点2:=探针;  //输出当前代码位置变量[探针]的结果,可以判断[探针]是否发生过修改。

日志分析：

//在第7行位置，变量[节点1]保存此时的[探针]结果为1，说明此时[探针]发生过修改；
//在第12行位置；变量[节点2]保存此时的[探针]结果为1，说明此时[探针]未发生过修改；
2024-03-28 13:44:04.689 Time:2024.03.28 13:44:00 Close:4260.0 开盘价:4300.000 探针:1.000 节点1:1.000 节点2:1.000

//在第7行位置，变量[节点1]保存此时的[探针]结果为0，说明此时[探针]未发生过修改；
//在第12行位置；变量[节点2]保存此时的[探针]结果为0，说明此时[探针]未发生过修改；
2024-03-28 13:45:03.687 Time:2024.03.28 13:45:00 Close:4200.0 开盘价:4260.000 探针:0.000 节点1:0.000 节点2:0.000

//在第7行位置，变量[节点1]保存此时的[探针]结果为1，说明此时[探针]发生过修改；
//在第12行位置；变量[节点2]保存此时的[探针]结果为2，说明此时[探针]发生过修改；
2024-03-28 13:46:02.700 Time:2024.03.28 13:46:00 Close:4260.0 开盘价:4250.000 探针:2.000 节点1:1.000 节点2:2.000

3. 避免在条件控制体内声明变量

• 在条件控制语句内声明的序列变量，在条件不成立时，会沿用最近一次成立时的有效值。
• 在代码的条件控制之外声明并初始化变量，有助于提升代码逻辑的健壮性。（见标签页[优化后代码]）

if time=134600 then begin
//条件判断中的变量
    探针:=time;
end

日志分析

//当time<134400时，条件不成立，但是变量名[探针]同样被打印输出，其结果默认为0.
2024-03-28 13:44:04.689 Time:2024.03.28 13:44:00 Close:4256.2 探针:0.000
2024-03-28 13:45:03.687 Time:2024.03.28 13:45:00 Close:4251.8 探针:0.000

//当time=134600时，条件成立，变量名[探针]的结果被修改成当前的K线时间time
2024-03-28 13:46:02.700 Time:2024.03.28 13:46:00 Close:4252.4 探针:134600.000

//当time>134600时，条件不成立,但是变量名[探针]依旧被输出,结果为上次条件成立时的结果。
//如何解决标记1中，关于探针变量结果错误的问题?(见示例2)。
2024-03-28 13:47:02.685 Time:2024.03.28 13:47:00 Close:4253.0 探针:134600.000^[1]

//序列变量[探针]定义并声明在代码主干中，确保在每根上都可以被执行到。
探针:=0;
if time=134600 then begin
//条件判断中的变量
    探针:=time;
end

日志分析

//变量[探针]完成初始化后，time<134400时，条件不成立，变量[探针]保持不变，最后的执行结果=0。
2024-03-28 13:44:04.689 Time:2024.03.28 13:44:00 Close:4256.2 探针:0.000
2024-03-28 13:45:03.687 Time:2024.03.28 13:45:00 Close:4251.8 探针:0.000

//变量[探针]完成初始化后，time=134600时，条件成立，变量[探针]赋值为K线时间，最后的执行结果=134600
2024-03-28 13:46:02.700 Time:2024.03.28 13:46:00 Close:4252.4 探针:134600.000

//变量[探针]完成初始化后，time>134600时，条件不成立,变量[探针]保持不变，最后的执行结果=0。
2024-03-28 13:47:02.685 Time:2024.03.28 13:47:00 Close:4253.0 探针:0.000

---

调试函数

当策略逻辑复杂或者变量众多时，使用监控输出功能得到日志会过于臃肿，反而不利于分析定位问题。因此我们可以通过在策略代码的特定关联位置中增加调试函数，已达到快速灵活处理问题。调试函数DEBUGFILE用法如下：

debugfile(文件保存路径,写入的文本内容,变量)

使用调试函数遵循以下技巧：

1. 反向定位：根据执行结果或者日志推导相关代码位置，然后自下而上寻找触发条件关联的因子结果。
2. 就近添加：添加中间变量输出时，变量应该写在待排查语句的前后位置，目的是避免因子在其它位置发生修改，产生误导。
3. 由粗到细：排查因子结果由粗到细，例如从组合条件-->各个子条件-->参与条件判断的因子。

1. 单一变量可直接使用打印控制符输出数值变量。多个变量可以使用多个debugfile函数处理。
2. 打印控制符%.xf,其中x为保留的小数位，例如%.2f为显示两位小数,%.0f则表示不显示小数。示例代码如下：

//"%.2f"为一个打印的控制符号,系统会将他替换为指定的一个数字输出,%.2f为显示两位小数,%.0f则表示不显示小数。
DEBUGFILE('D:\TEST.TXT','当前资产=%.2f',TASSET);
DEBUGFILE('D:\TEST.TXT','当前净持仓=%.0f',THOLDING);

日志输出

2024-03-31 09:09:15.279 当前资产=12345678.00
2024-03-31 09:09:15.279 当前净持仓=2

1. 将数值类型通过NUMTOSTR函数转换成字符串后，再逐个拼接成一个长字符串。然后一并打印的方式。
2. 字符串拼接规则使用&符号相连接。
3. 打印的字符串过长会影响策略执行效率。

//通过NUMTOSTR函数将多个数值分别转换成字符串后，使用'&' 将字符串拼接在一起即可。参数3位置可以填任意数值。
DEBUGFILE('D:\TEST.TXT','当前资产='&NUMTOSTR(TASSET,2) & '      当前持仓='&NUMTOSTR(THOLDING,0),1);

日志输出

2024-03-31 09:09:15.279 当前资产=12345678.00 当前持仓=2

示例：记录交易策略运行时的条件结果

使用dubugfile函数遵循就近添加、由粗到细的处理原则。完整的调试示例如下：

//中间变量
ma5:ma(close,5);
ma20:ma(close,20);
 
//开仓条件
con1:=cross(ma5,ma20);  //金叉
con2:=cross(ma20,ma5);  //死叉

//就近原则添加调试函数(即在con1 and tholding=0判断条件前后均可,可视情况灵活选择)
//增加ISLASTBAR条件判断可以减少debugfile函数的内部判断，从而增加运行效率。
if ISLASTBAR=1 then begin
    debugfile('D:\T_' & stklabel & '.txt',stklabel &'   [开仓条件='& numtostr(con1 and tholding=0,0)  &']'
        & '   各项条件：[开多条件1=' & numtostr(con1,0)&'   持仓手数='& numtostr(tholding,0)&']',0);
end
if con1 and tholding=0 then
    begin
         tbuy(1, 1, mkt);
   end


if ISLASTBAR=1 then begin
    debugfile('D:\T_' & stklabel & '.txt',stklabel &'   [平仓条件='& numtostr(con1 and tholding=0,0)  &']'
        & '   各项条件：[平仓条件1='& numtostr(con2,0)&'   持仓手数=' & numtostr(tholding,0) & ']',0);
end
if con2 and tholding=0 then
    begin
         tsell(1, 1, mkt);
    end

第9行解析

• 参数1：'D:\T_' & 'stklabel' & '.txt'
  • 日志写入的路径，此处的结构：'D:\T_' + 品种代码 + 文件名后缀。此处的品种代码是字符串变量，多品种时可以实现分别记录，避免混淆。
• 参数2：
  'stklabel' & ' [开仓条件=' & numtostr(con1 and tholding=0,0) & ']' & ' 各项条件：[开多条件1=' & numtostr(con1,0) & ' 持仓手数=' & numtostr(tholding,0) & ']'
  • 使用numtostr将开平仓条件、持仓转换成字符串后。与其他字符串拼接。以增加整个日志文件的可读性。
• 参数3：0 。
  • 任意数字，在此处没有实质性作用，仅是占位使用。

debugfile日志输出如下：

日志文件名：T_P00.txt

       1                    2         3                       4
----------------------------------------------------------------------------------
2022-04-08 10:06:00.284    P00   [开仓条件=0]   各项条件:[开多条件1=0   持仓手数=0]
2022-04-08 10:06:00.286    P00   [平仓条件=0]   各项条件:[平仓条件1=0   持仓手数=0]
2022-04-08 10:06:01.092    P00   [开仓条件=0]   各项条件:[开多条件1=0   持仓手数=0]
2022-04-08 10:06:01.092    P00   [平仓条件=0]   各项条件:[平仓条件1=0   持仓手数=0]
2022-04-08 10:06:01.096    P00   [开仓条件=0]   各项条件:[开多条件1=0   持仓手数=0]
2022-04-08 10:06:01.097    P00   [平仓条件=0]   各项条件:[平仓条件1=0   持仓手数=0]
......

---

调试工具

  在众多量化软件中，金字塔是少有提供可视化调试器的软件，公式调试器可以精确跟踪IF条件、FOR循环等控制语句的内部执行流程。也可以帮助资深用户深入分析全局变量、运行模式的等机制上的区别。

断点调试

断点调试可以在代码行的任意位置设定一个断点，当程序执行到该断点行后会自动停下，并告知当前最新的变量执行结果。设置方法：

1. 方法1：在指定代码行号位置处双击添加断点
2. 方法2：光标定位到指定代码行按快捷键
   F9

   设置断点的公式会在被执行的情况下遇到断点后自动打开公式编辑器并启动调试状态，包括在图表和后台的程序化交易过程中。

单步跟踪

   单步跟踪的作用是执行处于暂停等待状态下的公式，但每次只执行一行，这样我们就可以精细的看到公式行具体的执行过程与直接结果的变化情况。适用方法如下图：

1. 数据窗口显示当前所调试品种的主数据内容，介于序列模式和逐K线模式的不同，在逐K线模式下，会将当前的执行K线周期序号行置红色显示。
   
2. 变量窗口显示当前断点行或单步跟踪行的变量执行变化情况，介于序列与单值变量的不同，
   
   • 序列变量在点击“+”号会展开该变量的数列数组，而单值变量展开时只有一行。
   • 逐K线模式下只有单值数据这一种，返回当前执行的结果。如上图所示。

对比总结

功能	功能特点	功能局限性
图表调试	1. 可视化操作，符合技术分析使用习惯 2. 支持基于历史数据运算调试	1. 此方法反馈的都是历史数据最后一次的执行结果，无法反馈出K线当时执行时的结果。
监控输出	1. 设置简便，对调试要求不高 2. 以日志形式，输出全部变量本次执行的最后结果 3. 适用于简单的图表、后台程序化策略。	1.只支持实时输出，不支持回溯历史数据 2.日志冗余度受策略执行影响 3.日志量过大会增加日志分析难度
调试函数	1. 必须具备代码分析和调试定位能力。 2. 以日志形式，输出指定的变量、指定代码位置的实时执行结果 3. 适合精确跟踪控制语句内部执行流程 4. 适用于任意图表、后台程序化策略。	1.只支持实时输出，不支持回溯历史数据
调试工具	1. 适合精确跟踪控制语句内部执行流程	1. 调试效率偏低。 2. 支持回溯历史数据，不能连续反馈实时的执行结果