1分钟策略优化卡死在95%

Storm

策略很简单，只用到了std,ma,hhv,llv,ref,cross,every，这些最基本的函数，代码 不超过150行。回测rb00，1min，回测时间2021-1-1~2024-1-1，用了32核 。前面都挺快，但是到了95%，96%就卡死了 。  最后2个cpu一直满负荷，到现在都40分钟过去了
，

技术006

你取消重新试下。那两个核一直在计算，说明优化没有终止。如果可以稳定出现，可以提供下你的测试代码给我们排查下具体原因。

Storm

查到原因了,是every(,barpos-enterBar)函数造成的.以前从来没注意到这个问题,但是在小周期,大样本测试的时候差距非常明显

VARIABLE:enterBar=0;

M:=26;
N10:=2;
MID :  MA(c,M),LINETHICK2;
MAS:MA(MID,4),LINEDOT;
istd:STD(c,M),NODRAW;
UPPER1: MID + N10*istd;
LOWER1: MID - N10*istd;

dk:=cross(c,LOWER1);

if dk and holding=0 then
begin
        buy(1,2,MARKETR);
        enterbar:=barpos;
END

/////////////////写法一:耗时5分53秒
dp1:=cross(lower1,c);
cond1:=every(mid<mas,barpos-enterBar);
cond2:=every(mid<ref(mid,1),barpos-enterBar);
cond3:=every(mas<ref(mas,1),barpos-enterBar);
cond4:=every(mid<ref(mid,2),barpos-enterBar);
dp2:=(cond1 or cond2 or cond3 or cond4 ) and barpos-enterBar>10;
if holding>0 and (dp1 or dp2) then
begin
        sell(1,2,marketr);
END


/////////////////写法二:耗时1分35秒
dp1:=cross(lower1,c);
cond1:=every(mid<mas,barpos-enterBar+1);
cond2:=every(mid<ref(mid,1),barpos-enterBar+1);
cond3:=every(mas<ref(mas,1),barpos-enterBar+1);
cond4:=every(mid<ref(mid,2),barpos-enterBar+1);
dp2:=(cond1 or cond2 or cond3 or cond4 ) and barpos-enterBar>10;
if holding>0 and (dp1 or dp2) then
begin
        sell(1,2,marketr);
END


/////////////////写法三:耗时5分51秒,说明pel语言不具备短路求值的功能
dp1:=cross(lower1,c);
dp2:=barpos-enterBar>10 and (every(mid<mas,barpos-enterBar) or every(mid<ref(mid,1),barpos-enterBar) or every(mas<ref(mas,1),barpos-enterBar) or every(mid<ref(mid,2),barpos-enterBar));
if holding>0 and (dp1 or dp2) then
begin
        sell(1,2,marketr);
END


/////////////////写法四:耗时1分33秒.说明exist函数不存在这个问题
dp1:=cross(lower1,c);
cond1:=not(exist(mid>mas,barpos-enterBar));
cond2:=not(exist(mid>ref(mid,1),barpos-enterBar));
cond3:=not(exist(mas>ref(mas,1),barpos-enterBar));
cond4:=not(exist(mid>ref(mid,2),barpos-enterBar));
dp2:=(cond1 or cond2 or cond3 or cond4 ) and barpos-enterBar>10;
if holding>0 and (dp1 or dp2) then
begin
        sell(1,2,marketr);
END

技术006

every(mid<mas,barpos-enterBar);
barpos-enterBar=0时，代表从第一根k开始全部计算。
计算量肯定比barpos-enterBar+1（最小值是1，即只计算最近1根）的计算量大很多。

另外exist函数和every的的差异应该是算法上的区别。前者应该是找到成立即返回。而后者要一直算到最后位置才会返回。

Storm

我发现if(xx=0,1,h=hhv(h,xx))   当xx=0的时候h=hhv(h,xx)同样会计算.你们可以找个大样本测试数据跑一下就知道了. 我在跑优化的时候就发现
input:xx(0,0,5,1);
if(xx=0,1,h=hhv(h,xx)) ;
这句会导致优化卡死,改成xx(1,1,5,1)一下子就解决了.  建议你们优化一下if函数的逻辑,有助于提高常用函数if的运算效率.

admin

这和函数本身没有关系，是因为xx=0，在hhv(H,0)中代表取全部数据计算，自然计算量会很大。这个问题和4楼类似。
建议你提供可以复现的测试代码给我们。这样更有利于定位实际问题。

Storm

我的意思是if(xx=0,1,h=hhv(h,xx))  当xx=0的时候h=hhv(h,xx)根本就没有必要进行运算

技术006

Storm 发表于 2024-12-30 09:16
我的意思是if(xx=0,1,h=hhv(h,xx))  当xx=0的时候h=hhv(h,xx)根本就没有必要进行运算

逐k线计算中，hhv作为序列数据量类型的函数，他们必须都在每根k上都要有执行结果不支持将其选择性执行(这是底层计算机制要求) .  上面的代码等价于
HH:hhv(h,xx);
if(xx=0,1,h=hh) ;