代码怎样修改成固定手数一次平仓，不分批平仓？

汇智者-Lelouch

variable:zs=c,hl=c;//声明全局变量zs、hl
ma7:=ma(c,7);
ma21:=ma(c,21);
atr:=ma(h-l,21);//市场平均波动幅度
buycond:=cross(ma7,ma21);//平空开多条件
sellcond:=cross(ma21,ma7);//平多开空条件

if holding>0 then begin
多止损:zs;
if l<zs then sell(1,1,limitr,min(o,zs)-mindiff);
else if sellcond then sell(1,1,limitr,c);
end

if holding<0 then begin
空止损:zs;
if h>zs then sellshort(1,1,limitr,max(o,zs)+mindiff);
else if buycond then sellshort(1,1,limitr,c);
end

if holding=0 and buycond then begin//多头开仓
buy(7,1,limitr,c);
zs:=c-2*atr;
hl:=c;//hl开仓后的最有利价位，刚买入时，最有利价位为开仓价
end

if holding=0 and sellcond then begin//空头开仓
buyshort(7,1,limitr,c);
zs:=c+2*atr;
hl:=c;
end

if holding>0 and enterbars>0 and h>hl then begin//最高价抬升，止损位相应地抬升
hl:=h;
zs:=hl-2*atr;
end

if holding<0 and enterbars>0 and l<hl then begin//最低价下降，止损位相应地下移
hl:=l;
zs:=l+2*atr;
end


设置了大于1手的手数会分批平仓。 怎样修改成设置用修改的固定手数进出场，不分批平仓？


如图：
如果两个都设置1，就是固定下1手，也是一次平仓
如果设置1，7  就是下7手，然后分7次平仓


我需要修改成，下单固定手数，然后出场一次平仓，不分批平仓

技术010

参考如下，开仓和平仓语句的第2个参数是报单数量，不是第一个参数；开仓报7手，平仓用holding。
variable:zs=c,hl=c;//声明全局变量zs、hl
ma7:=ma(c,7);
ma21:=ma(c,21);
atr:=ma(h-l,21);//市场平均波动幅度
buycond:=cross(ma7,ma21);//平空开多条件
sellcond:=cross(ma21,ma7);//平多开空条件

if holding>0 then begin
多止损:zs;
if l<zs then sell(1,holding,limitr,min(o,zs)-mindiff);
else if sellcond then sell(1,holding,limitr,c);
end

if holding<0 then begin
空止损:zs;
if h>zs then sellshort(1,holding,limitr,max(o,zs)+mindiff);
else if buycond then sellshort(1,holding,limitr,c);
end

if holding=0 and buycond then begin//多头开仓
buy(1,7,limitr,c);
zs:=c-2*atr;
hl:=c;//hl开仓后的最有利价位，刚买入时，最有利价位为开仓价
end

if holding=0 and sellcond then begin//空头开仓
buyshort(1,7,limitr,c);
zs:=c+2*atr;
hl:=c;
end

if holding>0 and enterbars>0 and h>hl then begin//最高价抬升，止损位相应地抬升
hl:=h;
zs:=hl-2*atr;
end

if holding<0 and enterbars>0 and l<hl then begin//最低价下降，止损位相应地下移
hl:=l;
zs:=l+2*atr;
end

丹邈

技术010 发表于 2024-11-27 13:25
参考如下，开仓和平仓语句的第2个参数是报单数量，不是第一个参数；开仓报7手，平仓用holding。
variable: ...

好的，我复制了你修改后的代码。

比如我要设置成固定手数用3手，一次平仓

是否如下这样设置的就可以？


if holding=0 and buycond then begin//多头开仓
buy(1,3,limitr,c);
zs:=c-2*atr;
hl:=c;//hl开仓后的最有利价位，刚买入时，最有利价位为开仓价
end

if holding=0 and sellcond then begin//空头开仓
buyshort(1,3,limitr,c);
zs:=c+2*atr;
hl:=c;
end



第二个数字设置成3，第一个数字代表什么呢？需要怎样设置？

技术010

是的

丹邈

技术010 发表于 2024-11-27 13:44
是的

您好，根据你的指导，现在已经可以是一次平仓。
这个策略的是两个均线的关系，但策略本身没有参数项可以输入，怎样写成有两个参数项，可以分别设置两个均线的值呢？

技术010

那是因为你的代码中均线参数7和21在代码中写死了，可以用input来定义这个参数，例如：
input:n1(7,1,100,1),n2(21,1,100,1);
ma7:=ma(c,n1);
ma21:=ma(c,n2);