请老师帮忙编写公式

技术009

“210210,210603,210928”第一个日期我看错了，代码里没判断三连阳。是这个位置已经不是第一次突破前高了。



这个位置已经突破了而且也在A后面三个K以后了。第一次突破的位置又不满足其他条件就没有满足B了。

103610

技术009 发表于 2021-10-8 10:43
“210210,210603,210928”第一个日期我看错了，代码里没判断三连阳。是这个位置已经不是第一次突破前高了。 ...

可否在满足连续三天收盘价大于AA收盘价的情况下，再判断第一次突破前高呢

技术009

你是要先满足“连续三天收盘价大于AA收盘价”再判断突破前高？也就是这2个条件可能不是同时满足，而是顺序满足。

103610

技术009 发表于 2021-10-8 11:05
你是要先满足“连续三天收盘价大于AA收盘价”再判断突破前高？也就是这2个条件可能不是同时满足，而是顺序 ...

对，

技术009

[PEL] 复制代码

AA:=ref(ISDOWN,1) and ISUP and LLVBARS(l,20)<=1;
DRAWTEXT(AA,H+3*MINDIFF,'AA',COLORGREEN,0);

ALB:=VALUEWHEN(AA,LLVBARS(l,20));//在AA位置获取20周期最低点距离AA的周期跨度;返回值从0开始 
AL:=VALUEWHEN(AA,llv(l,20));//AA位置最低价(未必是AA最低价)
AC:=VALUEWHEN(AA,C);

LEN:=SUMBARS(AA,1)-1;//当前位置距离最近的AA的周期跨度;返回值从0开始
AAH:=HHV(H,LEN);//AA以后，不包含AA的最高价 也不包含当前K

条件1:count(ALL(C>AC,3),Len)>=1;//AA后第一个K到当前位置 满足过一次连续三个K收盘价大于AA位置的收盘价
条件2:ALL(L>AL,LEN);//满足所有K最低价大于AA位置获取的20周期最低价
条件3:count(C>REF(AAH,1),LEN-2)=1 AND C>REF(AAH,1);//AA后三个K后，第一次突破

//至少距离AA 3个K以上，否则无法满足“收盘价连续3天在AA收盘价之上”;
BB:=LEN>=3 AND count(ALL(C>AC,3),Len)>=1 AND ALL(L>AL,LEN) AND ISUP AND count(C>REF(AAH,1),LEN-3)=1 AND C>REF(AAH,1)  AND ALB+LEN+1<=9;
CC:=LEN>=3 AND  count(ALL(C>AC,3),Len)>=1 AND ALL(L>AL,LEN) AND ISUP AND count(C>REF(AAH,1),LEN-9)=1 AND C>REF(AAH,1)  AND ALB+LEN+1>10; 
DRAWTEXT(BB,H+3*MINDIFF,'BB',COLORYELLOW,0);
DRAWTEXT(CC,H+3*MINDIFF,'CC',COLORWHITE,0);
 

 

“矿石210208,210326,210601信号都延后了呢”这几个我对比了下，如果这几个位置信号算满足的话，就相当于把AA后第三个K位置本身的突破也算上了。目前代码是不包含，AA后第三个K的，只限于三个K以后的位置。

如果算上了的话，棉花9.28的信号就不满足了（其他几个类似）。因为第一次突破的位置刚好是AA后第三个K（9.27），而这个位置其他条件又不满足了。9.27位置不满足连续收盘价大于AA的收盘价。就是23号的收盘价是小于AA位置的收盘价的。

另外我把几个条件单独输出了，具体每个条件对应的含义见注释说明。这样能搞清楚到底哪个条件满足哪个不满足。

103610

技术009 发表于 2021-10-8 13:55
[mw_shl_code=pel,true]
AA:=ref(ISDOWN,1) and ISUP and LLVBARS(l,20)AC,3),Len)>=1;//AA后第一个K到当 ...

好的，明白了，就按现在的代码，麻烦老师帮我把剩下的公式完成吧

技术009

先把dd的部分补上，然后dd这里的逻辑也继承了我们前面讨论的2个地方
1.先判断连续三天的那个条件
2.从cc开始后三个K开始，不包含第三个K。

因为变量名有冲突了。改了些变量名称，逻辑没变。

[PEL] 复制代码

AA:=ref(ISDOWN,1) and ISUP and LLVBARS(l,20)<=1;
DRAWTEXT(AA,H+3*MINDIFF,'AA',COLORGREEN,0);

ALB:=VALUEWHEN(AA,LLVBARS(l,20));//在AA位置获取20周期最低点距离AA的周期跨度;返回值从0开始 
AL:=VALUEWHEN(AA,llv(l,20));//AA位置最低价(未必是AA最低价)
AC:=VALUEWHEN(AA,C);

LENA:=SUMBARS(AA,1)-1;//当前位置距离最近的AA的周期跨度;返回值从0开始
AAH:=HHV(H,LENA);//AA以后，不包含AA的最高价 也不包含当前K

//至少距离AA 3个K以上，否则无法满足“收盘价连续3天在AA收盘价之上”;
BB:=LENA>=3 AND count(ALL(C>AC,3),LENA)>=1 AND ALL(L>AL,LENA) AND ISUP AND count(C>REF(AAH,1),LENA-3)=1 AND C>REF(AAH,1)  AND ALB+LENA+1<=9;
CC:=LENA>=3 AND  count(ALL(C>AC,3),LENA)>=1 AND ALL(L>AL,LENA) AND ISUP AND count(C>REF(AAH,1),LENA-9)=1 AND C>REF(AAH,1)  AND ALB+LENA+1>10; 


LENC:SUMBARS(CC,1)-1;//当前位置距离最近的CC的周期跨度;返回值从0开始
CCH:=HHV(H,LENC);//CC以后，不包含CC的最高价 也不包含当前K
DD:=ALL(C>AL,LENC) and LENC>3  AND ISUP AND count(ALL(C>VALUEWHEN(CC,C),3),LENC)>=1 AND count(C>REF(CCH,1),LENC-3)=1 AND C>REF(CCH,1) ;

DRAWTEXT(BB,H+3*MINDIFF,'BB',COLORYELLOW,0);
DRAWTEXT(CC,H+3*MINDIFF,'CC',COLORWHITE,0);
DRAWTEXT(DD,H+3*MINDIFF,'DD',COLORWHITE,0);
 

103610

技术009 发表于 2021-10-9 13:55
先把dd的部分补上，然后dd这里的逻辑也继承了我们前面讨论的2个地方
1.先判断连续三天的那个条件
2.从cc ...

OK,很准确了

技术009

[PEL] 复制代码

FA:=ref(ISUP,1) and ISDOWN and HHVBARS(h,20)<=1;
DRAWTEXT(FA,H+3*MINDIFF,'FA',COLORGREEN,0);

FALB:=VALUEWHEN(FA, HHVBARS(h,20));
FAH:=VALUEWHEN(FA, HHV(h,20));
FAC:=VALUEWHEN(FA,C);

LENFA:=SUMBARS(FA,1)-1;
FAL:=LLV(L,LENFA);

FB:=LENFA>3 AND count(ALL(C<FAC,3),LENFA)>=1 AND ALL(H<FAH,LENFA) AND ISDOWN AND count(C<REF(FAL,1),LENFA-3)=1 AND C<REF(FAL,1)  AND FALB+LENFA+1<=9;
FC:=LENFA>3 AND count(ALL(C<FAC,3),LENFA)>=1 AND ALL(H<FAH,LENFA) AND ISDOWN AND count(C<REF(FAL,1),LENFA-9)=1 AND C<REF(FAL,1)  AND FALB+LENFA+1>10; 


LENFC:=SUMBARS(FC,1)-1;
FCL:=LLV(L,LENFC);
FD:=ALL(C<FAL,LENFC)  AND ISDOWN AND count(ALL(C<VALUEWHEN(FC,C),3),LENFC)>=1 AND count(C<REF(FCL,1),LENFC-3)=1 AND C<REF(FCL,1) ;

DRAWTEXT(FB,H+3*MINDIFF,'FB',COLORYELLOW,0);
DRAWTEXT(FC,H+3*MINDIFF,'FC',COLORWHITE,0);
DRAWTEXT(FD,H+3*MINDIFF,'FD',COLORWHITE,0);
 

FA-FD的。

103610

技术009 发表于 2021-10-11 13:24
[mw_shl_code=pel,true]FA:=ref(ISUP,1) and ISDOWN and HHVBARS(h,20)3 AND count(ALL(C=1 AND ALL(H

FD识别不到，检查了一遍公式没发现问题出在哪里，麻烦老师再帮我看看