创业板涨停跌停问题

100018535

请问老师，创业板涨停跌停如何写代码？

技术008

a:c/callstock(stklabel,vtclose,6,-1)>1.19

100018535

技术008 发表于 2025-2-17 10:09
a:c/callstock(stklabel,vtclose,6,-1)>1.19

请问老师，创业板跌停如何写

技术008

b:(callstock(stklabel,vtclose,6,-1)-c)/callstock(stklabel,vtclose,6,-1)>1.2

100018535

烦请老师把沪深主板涨跌停10%的代码也 写一下，我的交易系统常用到，
具体是遇见涨停跌停不交易又该如何写？

技术008

d1:callstock('',vtclose,6,-1);//昨日收盘价
isst:strfind(stkname,'st',1);//是否st
iszb:(strleft(stklabel,2)='60' or strleft(stklabel,2)='00');//区分是否主板
ztv:if(isst,if(iszb,0.05,0.10),if(iszb,0.1,0.2));//创业板规则复杂，涨跌停数值不确定，最好不要应用在这上面。

//这里的处理是为了处理数学上计算的偏差
ztp:round((ztv+1)*round(d1/0.01))/100;//涨停价
dtp:round((-ztv+1)*round(d1/0.01))/100;//跌停价
zt:ztp=ROUNDS(c,2);//仅对主板a股以及科创，创业板有效。

100018535

技术008 发表于 2025-2-17 11:10
d1:callstock('',vtclose,6,-1);//昨日收盘价
isst:strfind(stkname,'st',1);//是否st
iszb:(strleft(stk ...

如果出现涨停跌停不交易如何表达？

技术008

zt返回1表示涨停

那你就开仓条件加一个zt=0就可以了

100018535

技术008 发表于 2025-2-17 11:20
zt返回1表示涨停

那你就开仓条件加一个zt=0就可以了

//a0-唐限f30+wbt
//f30参数3-38利395hb1498hc23jy22
//f15参数17-15利108hb35hc11jy61

input:x(4,1,60,1),y(26,1,60,1),
ss(999000,100,999000,100),;

//t1限价模块
closeposmode:1; //指定图表理论平仓模式为优先平老仓
oddlotsmode:1;  //不允许零股交易，例如股票将按照最小100股单位调整
可平:=holding-dayholding;//可平>0,可平,
手数:=ss;

//涨停跌停不交易模块限价

d1:callstock('',vtclose,6,-1);//昨日收盘价
isst:strfind(stkname,'st',1);//是否st
iszb:(strleft(stklabel,2)='60' or strleft(stklabel,2)='00');//区分是否主板
ztv:if(isst,if(iszb,0.05,0.10),if(iszb,0.1,0.2));//创业板规则复杂，涨跌停数值不确定，最好不要应用在这上面。

//这里的处理是为了处理数学上计算的偏差
ztp:round((ztv+1)*round(d1/0.01))/100;//涨停价
dtp:round((-ztv+1)*round(d1/0.01))/100;//跌停价
zt:ztp=ROUNDS(c,2);//仅对主板a股以及科创，创业板有效。
//and zt=0

//中间变量
x周期高点:ref(hhv(h,x),1),pointdot,colorred;
y周期低点:ref(llv(l,y),1),pointdot,colorgreen;

//正常交易条件
开多条件:=high>=x周期高点 and o<=x周期高点 and zt=0 and holding<=0,;
平多条件:=low <=y周期低点 and o>=y周期低点 and zt=0 and holding>=0,;

//交易系统
平多:sell(平多条件 and 可平>0,手数,limitr,y周期低点),;
开多:buy (开多条件,手数,limitr,x周期高点),;

当前持仓:holding,colorgray,linethick0;
当前资产:asset,noaxis,colorgray;//输出当前资产，但不影响坐标最高最低值


补充内容 (2025-2-17 11:34):
跌停也是zt=0 吗？

补充内容 (2025-2-17 11:35):
请老师看看对不对？

技术008

//这里的处理是为了处理数学上计算的偏差
ztp:round((ztv+1)*round(d1/0.01))/100;//涨停价
dtp:round((-ztv+1)*round(d1/0.01))/100;//跌停价
zt:ztp=ROUNDS(c,2);//仅对主板a股以及科创，创业板有效。
dt:dtp=ROUNDS(c,2);

跌贴是dt，自己在定义一个，zt和dt分别表示返回1表示涨停和跌贴，你要求
zt=0 and dt=0就可以了