老师，你好，求帮忙!

李斌业

这个是标准版图表量化模式，帮忙改成专业版后台模式，谢谢1
pd:=macd<ref(macd,1) and diff<ref(diff,1);
pk:=macd>ref(macd,1) and diff>ref(diff,1);
if kd1 and kd2 and holding=0 and kc and duo=1  then buy(1,ss,marketr);
if kk1 and kk2 and holding=0 and kc and kong=1 then buyshort(1,ss,marketr);

if c-ENTERPRICE>ying*mindiff  and enterbars>0 and holding>0 and duo=1 then 多赢:sell(1,holding,thisclose);
if ENTERPRICE-c>ying*mindiff and enterbars>0 and holding<0 and kong=1 then 空赢:sellshort(1,holding,thisclose);

if ENTERPRICE-c>kui*mindiff and holding>0 and duo=1 then 多损:sell(1,holding,thisclose);
if c-ENTERPRICE>kui*mindiff and holding<0 and kong=1 then 空损:sellshort(1,holding,thisclose);

技术009

[PEL] 复制代码

pd:=macd<ref(macd,1) and diff<ref(diff,1);
pk:=macd>ref(macd,1) and diff>ref(diff,1);

多持仓均价:TAVGENTERPRICEEX2('','',0);
空持仓均价:TAVGENTERPRICEEX2('','',1);

多可用持仓:TBUYHOLDINGEX('','',1);
空可用持仓:TSELLHOLDINGEX('','',1);

if kd1 and kd2 and 多可用持仓=0 and kc and duo=1  then tbuy(1,ss,mkt);
if kk1 and kk2 and 空可用持仓=0 and kc and kong=1 then tbuyshort(1,ss,mkt);

if c-多持仓均价>ying*mindiff  and tenterbars>0 and 多可用持仓>0 and duo=1 then 多赢:tsell(1,0,lmt,DYNAINFO( 28));
if 空持仓均价-c>ying*mindiff and tenterbars>0 and 空可用持仓>0 and kong=1 then 空赢:tsellshort(1,0,lmt,DYNAINFO( 34));

if 多持仓均价-c>kui*mindiff and 多可用持仓>0 and duo=1 then 多损:tsell(1,0,lmt,DYNAINFO( 28));
if c-空持仓均价>kui*mindiff and 空可用持仓>0 and kong=1 then 空损:tsellshort(1,0,lmt,DYNAINFO( 34));

李斌业

谢谢！

李斌业

老师，你好，问下，策略中（28）和（34）原稿中没有，现在加上了，代表什么？

技术009

买一价，卖一价。

https://www.weistock.com/docs/PE ... D%E6%95%B0%E7%BB%84

参考动态行情列表。

李斌业

老师，不用回答了。

李斌业

老师，你在百忙之中，回答了，让我学到了很多知识，再一次谢谢你！！

李斌业

老师，你好，改好的策略用的很好。是我的过错，没有把原策略发全，现在的后台开仓信号有点多，我现在把原稿发过来 ，不好意思，老师，又麻烦你，改成后台模式，谢谢，再一次感谢！！！！！

duo:=1;//1意思是允许开多，0意思是不允许开多
kong:=0;//1意思是允许开空，0意思是不允许开空
input:ss(2,1,100,1),//手数
x(0.2966.0,0.01,1000,0.01),
ying(50,1,1000,1),
kui(15,1,1000,1),
d1(2,1,1000,1),
d2(4,1,1000,1),
d3(8,1,1000,1);
PBX1:=(EMA(CLOSE,4)+MA(CLOSE,4*2)+MA(CLOSE,4*4))/3;
PBX2:=(EMA(CLOSE,6)+MA(CLOSE,6*2)+MA(CLOSE,6*4))/3;
PBX3:=(EMA(CLOSE,9)+MA(CLOSE,9*2)+MA(CLOSE,9*4))/3;
PBX4:=(EMA(CLOSE,13)+MA(CLOSE,13*2)+MA(CLOSE,13*4))/3;
PBX5:=(EMA(CLOSE,18)+MA(CLOSE,18*2)+MA(CLOSE,18*4))/3;
PBX6:=(EMA(CLOSE,24)+MA(CLOSE,24*2)+MA(CLOSE,24*4))/3;
DIFF := EMA(CLOSE,d1) - EMA(CLOSE,d2);
DEA  := EMA(DIFF,d3);
MACD := 2*(DIFF-DEA), COLORSTICK;
jc:cross(diff,dea);
sc:cross(dea,diff);
kd1:jc and macd>0 and macd>ref(macd,1) and dea>0 and dea>ref(dea,1) and diff>0 and diff>ref(diff,1) and o<c;
kk1:sc and macd<0 and macd<ref(macd,1) and dea<0 and dea<ref(dea,1) and diff<0 and diff<ref(diff,1) and o>c;
kd2:=c>PBX1 and c>PBX2 and c>PBX3 and c>PBX4 and c>PBX5 and c>PBX6;
kk2:=c<PBX1 and c<PBX2 and c<PBX3 and c<PBX4 and c<PBX5 and c<PBX6;
kc:=abs(dea-0)<x;
//up5f:=stkindi('','b1.up',0,22,-1);
//down5f:=stkindi('','b1.down',0,22,-1);
pd:=macd<ref(macd,1) and diff<ref(diff,1);
pk:=macd>ref(macd,1) and diff>ref(diff,1);
if kd1 and kd2 and holding=0 and kc and duo=1  then buy(1,ss,marketr);
if kk1 and kk2 and holding=0 and kc and kong=1 then buyshort(1,ss,marketr);

if c-ENTERPRICE>ying*mindiff  and enterbars>0 and holding>0 and duo=1 then 多赢:sell(1,holding,thisclose);
if ENTERPRICE-c>ying*mindiff and enterbars>0 and holding<0 and kong=1 then 空赢:sellshort(1,holding,thisclose);

if ENTERPRICE-c>kui*mindiff and holding>0 and duo=1 then 多损:sell(1,holding,thisclose);
if c-ENTERPRICE>kui*mindiff and holding<0 and kong=1 then 空损:sellshort(1,holding,thisclose);

技术009

不需要进一步修改了。就你上面这个代码指标计算这个部分图表和后台是一样的。
你直接替换下前面修改的那部分就行了。

李斌业

好的，我下午再试试，有事再请教！！谢谢老师！！！