帮忙改一下老师

鑫659448

技术009 发表于 2021-11-8 14:59
你跨周期的调用，调用的信号也是要有一套逻辑的啊。你不说难道我随便写个调用了啊，比如调用大周期的ma5>ma ...

现在做这个不是跨周期的，只是单纯的单周期，没有大周期的判定·

鑫659448

价格高于MA 40 `  出现信号就开仓了·

鑫659448

技术009 发表于 2021-11-8 14:59
你跨周期的调用，调用的信号也是要有一套逻辑的啊。你不说难道我随便写个调用了啊，比如调用大周期的ma5>ma ...

空的逻辑里面少了一个·  信号K低点小于前低  L<前L

鑫659448

技术009 发表于 2021-11-8 14:59
你跨周期的调用，调用的信号也是要有一套逻辑的啊。你不说难道我随便写个调用了啊，比如调用大周期的ma5>ma ...

老师辛苦了，弄好了吗·？

技术009

把你的需求完整的整理一份。你帖子里的描述  我没办法整理清楚。

鑫659448

MA40:MA(C,40);



DRAWTEXT(C>MA40&&L>MA40&&C>REF(C,1)&&C>REF(O,1)&&O>=REF(O,1)&&H>REF(H,1)&& ABS(H-L)<=100*MINPRICE&&O>MA40+10*MINPRICE,H+3,'A'),VALIGN0;





DRAWTEXT(C<MA40&&H<MA40&&C<REF(C,1)&&C<REF(O,1)&&H<REF(H,1)&& ABS(H-L)<=100*MINPRICE&&O<MA40-10*MINPRICE,H+5,'B'),VALIGN0;


单周期：思路就是围绕MA 等信号的出现，信号逻辑就是上面的指标。

里面的变量有：
1 MA40   
2：ABS(H-L)<=70*MINPRICE 信号线的大小的限定  
3：信号K线距离均线空间的大小 O<MA40-10*MINPRICE
4：止盈是变量


开仓：出现多信号，高于信号K线高点一跳挂单。出现空信号，低信号K线低点一跳挂单

止损：每当最新的K线走完，马上移动到最新K线的 最低点之下加3跳止损（空单是最高点之上3跳）

止盈为：100-200跳（变量）

有持仓，出信号不再开新仓。等平仓后，出新的信号在开仓。


出现信号后挂单未成交，当根K线最后3秒撤单。  收盘前10分钟停止运行交易（夜盘，上午，下午）

鑫659448

麻烦你了·009 老师

技术009

2：ABS(H-L)<=70*MINPRICE 信号线的大小的限定  
3：信号K线距离均线空间的大小 O<MA40-10*MINPRICE

这2个啥意思。开仓的条件？开多还是开空的？还是都使用这2个限制条件。

鑫659448

2 这个是对信号K大小的限定，不能超过多少。超过不符合开仓条件，多空都有。


3
DRAWTEXT(C>MA40&&L>MA40&&C>REF(C,1)&&C>REF(O,1)&&O>=REF(O,1)&&H>REF(H,1)&& ABS(H-L)<=100*MINPRICE&&O>MA40+10*MINPRICE,H+3,'多'),VALIGN0;


DRAWTEXT(C<MA40&&H<MA40&&C<REF(C,1)&&C<REF(O,1)&&H<REF(H,1)&& ABS(H-L)<=100*MINPRICE&&O<MA40-10*MINPRICE,H+5,'空'),VALIGN0;

多和空里面都有，这是个信号的过滤，意思是（不能在均线附近，要远离均线）

补充内容 (2021-11-9 12:44):
这样能清楚吗？老师

技术009

[PEL] 复制代码

INPUT:X(40,1,200,1),ss(1,1,200,1),N(100,1,200,1);//X是均线参数，SS是手数，N是止盈的点数,默认是100点
MA40:MA(C,X);


FOR I=0 TO 3 DO  //循环变量每个收盘时间来进行判断
BEGIN 
abb:=timetot0(CLOSETIME(I))-time0,NODRAW;//当前K线时间距离收盘K线结束倒计时 
abb3:=timetot0(CLOSETIME(I))-timetot0(dynainfo(207)),NODRAW;//当前时间距离收盘K时间        
IF         (ISLASTBAR and  abb3>=0 and abb3<10*60) THEN MARK:=1;
END




多止损:l<ref(l,1)-3*mindiff and  TORDERPRICE(1,1)>0;//最新价小于前一个k最低价-1跳 止损;且前面有开仓信号
空止损:h>ref(h,1)+3*mindiff and TORDERPRICE(1,3)>0;//最新价大于前一个k最高价+1跳 止损
 
//完善止盈止损的判断。1.判断上次信号到底是什么信号 2.判断当前后台程序化前面有无开仓
多止盈:TTYPE(1)=1 and  c-TORDERPRICE(1,1) >=N*MINDIFF  and  TORDERPRICE(1,1)>0;//盈利N跳 止盈
空止盈:TTYPE(1)=3 and  TORDERPRICE(3,1)-c>=N*MINDIFF and TORDERPRICE(1,3)>0;
 
tsell(多止损  and tbuyholdingex('','',1)>0 and not(MARK),tbuyholdingex('','',1),mkt);
tsellshort(空止损 and tsellholdingex('','',1)>0 and not(MARK),tsellholdingex('','',1),mkt);
 
tsell(多止盈 and tbuyholdingex('','',1)>0 and not(MARK),tbuyholdingex('','',1),mkt);
tsellshort(空止盈 and tsellholdingex('','',1)>0 and not(MARK),tsellholdingex('','',1),mkt);
 

//开多，开空条件
kd:C>MA40 and L>MA40 and C>REF(C,1) and C>REF(O,1) and O>=REF(O,1) and H>REF(H,1) and  ABS(H-L)<=70*MINDIFF and O>MA40+10*MINDIFF;
kk:C<MA40 and H<MA40 and C<REF(C,1) and C<REF(O,1) and H<REF(H,1) and  ABS(H-L)<=70*MINDIFF and O<MA40-10*MINDIFF;
 
t:time0-timetot0(dynainfo(207));//距离最K结束的时间(秒)  仅在最后一个K正常输出。
 
 
tbuy(kd and TBUYHOLDINGEX('','',1)=0 and not(MARK),ss,lmt,h+1*mindiff);//开多
tbuyshort(kk and TSELLHOLDINGEX('','',1)=0 and not(MARK),ss,lmt,l-1*mindiff);//开空
 
 
if TISPRVREMAIN(1) and t<=3 then TCANCELEX(1,1,'',STKLABEL);// 不满足突破条件了，在K线结束前3秒进行撤单操作。
if TISPRVREMAIN(3) and t<=3 then TCANCELEX(1,3,'',STKLABEL);
 
if TENTERBARS(1)=1 and TISPRVREMAIN(1)  then TCANCELEX(1,1,'',STKLABEL);
if TENTERBARS(1)=1 and TISPRVREMAIN(3)  then TCANCELEX(1,3,'',STKLABEL);