高点问题

技术009 · 发表于 2022-9-27 14:37

你那个条件有时候不连续，这个就很麻烦。

截图202209271434323330.png

所以前面我那个例子是用全局变量做的标记。来判断红绿区间的转换，因为直接判断它会出现无效值了。

就是这个不满足的那一段区间导致很多麻烦，否则用 BACKSET 应该是可以实现的。我再看看吧。

pxr019225 · 发表于 2022-9-27 14:38

这高点都在10平均线下面了，低点都在10平均线上面了

pxr019225 · 发表于 2022-9-27 15:48

技术009 发表于 2022-9-27 14:37
你那个条件有时候不连续，这个就很麻烦。

那个框内反向3K不成立那继续找低点，直到向上3K成立然后向上延续再循环直到低点条件成立，构成一个闭环反复循环。高点都是最高价，低点都是最低价。

技术009 · 发表于 2022-9-27 16:38

新建一个被调用指标T1,模式必须选择逐K模式:

[PEL] 复制代码

ma20:ma(c,20);
HX:DRAWNULL;
H1:=HHV(H,3);
IF  ALL(L>MA20,3) THEN HX:=H1;


LX:DRAWNULL,NODRAW;
L1:=LLV(L,3);
IF  ALL(H<MA20,3) THEN LX:=L1;


showH:HX,COLORRED;
showL:lx,COLORGREEN;

VARIABLE:mark:=0;

if HX then mark:=1;
if lx then mark:=-1;
lzh:ref(mark=-1,1) and  mark=1;
hzl:ref(mark=1,1) and  mark=-1;

实际画线指标代码如下，务必选择序列模式：

[PEL] 复制代码

ma20:ma(c,20);
hx:"T1.showH",COLORRED;
lx:"T1.showL",COLORGREEN;

lzh:="T1.lzh";
hzl:="T1.hzl";

LEN1:=BARSLAST(lzh)+1;
LEN2:=BARSLAST(hzl)+1;
redV:=if(VALID(hx),hx,0),NODRAW;
redH_location:=HHVBARS(redV,len1);
greenV:=if(VALID(lx),lx,1000000),NODRAW;
greenL_location:=LLVBARS(greenV,LEN2);

S1:BACKSET(hzl,redH_location+1);
S2:BACKSET(lzh,greenL_location+1);

DRAWICON(cross(s1,0),h,1);
DRAWICON(cross(s2,0),L,2);

DRAWLINE(cross(s1,0),H,cross(s2,0) OR ISLASTBAR,L,0);
DRAWLINE(cross(s2,0),L,cross(s1,0) OR ISLASTBAR,H,0);

效果如下：