公式问题，谢谢

王颖辉

您好，

下面是系统自带的公式，请帮忙加上当日收盘前5分钟全部平仓的指令，谢谢。
第二天是否正常有信号就做?如果改完



INPUT:M(50,5,300,30),N(1.25,0.1,10,0.1),D(30,1,100,1),SS(1,1,10000,1);
VARIABLE:X:=50;
MID :  MA(CLOSE,M);//布林中轨
UPPER:MID + N*STD(CLOSE,M);//布林上轨
LOWER:MID - N*STD(CLOSE,M);//布林下轨
CYC:=ENTERBARS+1,NOAXIS;//开仓至今的周期数
HC30:=REF(HHV(C,D),1);//30周期收盘价高点
LC30:=REF(LLV(C,D),1);//30周期收盘价低点
手数:=SS;
出场MA:MA(CLOSE,IF(HOLDING<>0,IF(CYC>=40,10,51-CYC),50));

//交易条件
开多平空条件:=C>HC30 AND H>REF(UPPER,1);//收盘价大于30周期收盘价最高值，且最高价上穿上轨
开空平多条件:=C<LC30 AND L<REF(LOWER,1);//收盘价小于30周期收盘价最高值，且最低价下穿下轨
多头出场条件:=C<出场MA AND 出场MA<UPPER;
空头出场条件:=C>出场MA AND 出场MA>LOWER;
//交易系统
多头出场:SELL(多头出场条件 AND HOLDING>0,手数,LIMITR,C);
空头出场:SELLSHORT(空头出场条件 AND HOLDING<0,手数,LIMITR,C);

平空:SELLSHORT(开多平空条件 AND HOLDING<0,手数,LIMITR,C);
平多:SELL(开空平多条件 AND HOLDING>0,手数,LIMITR,C);
开空:BUYSHORT(开空平多条件 AND HOLDING>=0,手数,LIMITR,C);
开多:BUY(开多平空条件 AND HOLDING<=0,手数,LIMITR,C);
//注意先平后开原则

当前持仓:HOLDING,COLORGRAY,LINETHICK0;
当前资产:ASSET,NOAXIS,COLORGRAY;//输出当前资产，但不影响坐标最高最低值

技术009

你运行的周期 是什么周期？

王颖辉

5分钟

技术009

实际交易时候：
如果是走完K模式：
if time=185500 then
begin
sell(1,holding,market);
sellshort(1,holding,market);        
END

如果是固定轮训模式：
if time=190000 then
begin
sell(1,holding,market);
sellshort(1,holding,market);        
END

王颖辉

您好，

把上面代码直接加上就行是吗？谢谢

技术006

是的，根据模式选择添加即可。