后台，不符合条件，开仓了

技术007

后台预警,交易的股票 不对   3、4、、6、、7 等股票都不符合信号  但是开仓了,啥原因(后附代码)
,

TR1:= SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),14);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SUM(IF(HD>0 AND HD>LD,HD,0),14);
DMM:= SUM(IF(LD>0 AND LD>HD,LD,0),14);
PDI:=DMP*100/TR1;
MDI:=DMM*100/TR1;
ADX:=MA(ABS(MDI-PDI)/(MDI+PDI)*100,6);
ADXR:=(ADX+REF(ADX,6))/2;
黄线小于全部:=MDI<PDI and MDI<ADX and MDI<ADXR;

// 基础条件
price_cond := close > 5 and close < 80;  // 价格大于5元小于80元
market_cap := FINANCE(7)*close < 30000000000;  // 流通市值小于300亿元
pe_cond := DYNAINFO( 39) > 0;  // 市盈率大于0
st_cond := not(STRICMP(STRLEFT(stkname,2 ),'st') = 0 or STRICMP(STRLEFT(stkname,3 ), '*st') = 0 );  // 非ST股票

// MACD条件
DIFF :EMA(CLOSE,12) - EMA(CLOSE,26);
DEA  :=EMA(DIFF,9);
MACD :=2*(DIFF-DEA);

macd_cond := MACD >= 0 and DIFF >= 0;  // MACD和DIF大于等于零

// 换手率条件
turnover := SUM(VOL/CAPITAL*100,3) > 5;  // 前3日累计换手率大于5%

// 涨幅条件
rise_cond := (CLOSE/REF(CLOSE,5)-1)*100 < 15;  // 5日内涨幅小于15%

// 开仓条件
ma4 := MA(CLOSE,4);  // 4日均线
cross_cond := CROSS(CLOSE,ma4) and CLOSE > ma4;  // 上穿4日均线且收盘价大于4日均线
high_cond := HIGH > REF(HIGH,1) and (high/REF(CLOSE,1)-1)*100 < 5;  // 今日最高价超过昨日最高价且高开小于5%
buy_condition := price_cond and market_cap and pe_cond and st_cond and macd_cond and turnover and rise_cond and REF(cross_cond,1) and high_cond;

// 平仓条件1：跌破4日均线
exit_cond1 := CROSS(ma4,CLOSE) and CLOSE < ma4 and LOW < REF(LOW,1);  // 跌破4日均线且下根K线最低点跌破前根K线最低点

// 平仓条件2：涨停板打开
exit_cond2 := (HIGH >= REF(CLOSE,1)*1.09) and CLOSE < REF(CLOSE,1)*1.09;  // 涨停板打开

// 平仓条件3：主板冲高回落
exit_cond3_main := (HIGH/REF(CLOSE,1)-1)*100 >= 8 and (CLOSE/HIGH-1)*100 <= -2;  // 主板冲高8%回落2%

// 平仓条件3：创业板科创板北交所冲高回落
exit_cond3_gem := (STRFIND(MARKETLABEL,'688',1) > 0 OR STRFIND(MARKETLABEL,'300',1) > 0 OR STRFIND(MARKETLABEL,'8',1) > 0) AND
                  (HIGH/REF(CLOSE,1)-1)*100 >= 11 and (CLOSE/HIGH-1)*100 <= -3;  // 创业板科创板北交所冲高11%回落3%

// 平仓条件4：持股大于3天涨幅3-5%回落1%
exit_cond4 := tENTERBARS(0) >= 3 and (CLOSE/TAVGENTERPRICE-1)*100 > 3 and (CLOSE/TAVGENTERPRICE-1)*100 < 5 and
               (CLOSE/HHV(HIGH,tENTERBARS(0)+1)-1)*100 <= -1;

// 平仓条件5：持股大于1天涨幅6-8%回落1%
exit_cond5 := tENTERBARS(0) >= 1 and (CLOSE/TAVGENTERPRICE-1)*100 > 6 and (CLOSE/TAVGENTERPRICE-1)*100 < 8 and
               (CLOSE/HHV(HIGH,tENTERBARS(0)+1)-1)*100 <= -1;

// 综合平仓条件
exit_condition := exit_cond1 or exit_cond2 or exit_cond3_main or exit_cond3_gem or exit_cond4 or exit_cond5;

// 交易系统
tBUY(黄线小于全部>0 and buy_condition and tbuyholding(1)=0, 1000, mkt);  // 满足开仓条件时做多1手
tSELL(exit_condition, tbuyholding(0), mkt);  // 满足平仓条件时平仓全部持仓

技术008

建议配合debugfile输出下开仓条件看下
另外工具-数据补充，补充下数据看下是不是数据缺失导致的