不执行平仓指令，时间设置不对吗？

徐文涛

INPUT:SS(1,1,10000,10);
手数:=1;
N:=BARSLAST(DATE<>REF(DATE,1));
昨高:=CALLSTOCK(STKLABEL,VTHIGH,6,-1);//昨高
昨低:=CALLSTOCK(STKLABEL,VTLOW,6,-1);//昨低
昨收:=CALLSTOCK(STKLABEL,VTCLOSE,6,-1);//昨收
今高:=VALUEWHEN(TODAYBAR>1,HHV(H,TODAYBAR));
今低:=VALUEWHEN(TODAYBAR>1,LLV(L,TODAYBAR));

观察卖出价:昨高+0.35*(昨收-昨低);//SSETUP
反转卖出价:(1.07/2)*(昨高+昨低)-0.07*昨低;//SENTER
反转买入价:(1.07/2)*(昨高+昨低)-0.07*昨高;//BENTER
观察买入价:昨低-0.35*(昨高-昨收);//BSETUP
突破买入价:(观察卖出价+0.25*(观察卖出价-观察买入价));//BBREEAK
突破卖出价:观察买入价-0.25*(观察卖出价-观察买入价);//SBREAK

//条件
空仓做多条件:=C>突破买入价 AND HOLDING=0;
空仓做空条件:=C<突破卖出价 AND HOLDING=0;
多单反转条件:=HOLDING>0 AND 今高>观察卖出价 AND C<反转卖出价;
空单反转条件:=HOLDING<0 AND 今低<观察买入价 AND C>反转买入价;

//由于时间进制不同，时间加减需要换算成秒处理后，再转化成时间
//开盘后20分钟
BEGIN_TIME:=T0TOTIME(TIMETOT0(OPENTIME(1))+20*60);
//收盘前5分钟
END_TIME:T0TOTIME(TIMETOT0(CLOSETIME(0))-5*60);

//交易系统
IF TIME>=BEGIN_TIME AND TIME<END_TIME THEN BEGIN
        空仓开多:BUY(空仓做多条件,手数,MARKET);
        空仓开空:BUYSHORT(空仓做空条件,手数,MARKET);
//多单反转:
IF 多单反转条件 THEN BEGIN
          平多:SELL(1,手数,MARKET);
          翻空:BUYSHORT(1,手数,MARKET);
END
//空单反转:
IF 空单反转条件 THEN BEGIN
        平空:SELLSHORT(1,手数,MARKET);
        翻多:BUY(1,手数,MARKET);
END
END

技术008

IF T0TOTIME(TIME)>=BEGIN_TIME AND T0TOTIME(TIME)<END_TIME THEN BEGIN


时间也要转换出去才能比较
否者就是拿时间和秒比较就不行了

徐文涛

技术008 发表于 2025-4-27 09:05
IF T0TOTIME(TIME)>=BEGIN_TIME AND T0TOTIME(TIME)

问题还是没解决啊‘’‘’‘’‘要怎么’改动，把这一句加在哪里？还是要这一句替换掉某一句？谢谢！麻烦详细说说

技术008

IF T0TOTIME(TIME)>=BEGIN_TIME AND T0TOTIME(TIME)<END_TIME THEN BEGIN
        空仓开多:BUY(空仓做多条件,手数,MARKET);
        空仓开空:BUYSHORT(空仓做空条件,手数,MARKET);
//多单反转:
IF 多单反转条件 THEN BEGIN
          平多:SELL(1,手数,MARKET);
          翻空:BUYSHORT(1,手数,MARKET);
END
//空单反转:
IF 空单反转条件 THEN BEGIN
        平空:SELLSHORT(1,手数,MARKET);
        翻多:BUY(1,手数,MARKET);
END
END



就是你时间控制这里的编写，这个代码是你自己编写的吗，自己编写的应该很了解自己的时间流是在哪里的
所有时间判断都要转换秒以后去对比