请教

Mr.Virgo

请老师编写一个三条均线的程序：
均线分别为：日线20均线；分钟30、60；
当分钟均线金叉且在日线20均以上做多，死叉平多；当盈利超过100跳，回撤30跳也平仓，平仓后不在开仓，等待下一个信号；
当分钟均线死叉且在日线20日以下做空，金叉平空；当盈利超过100跳，回撤30跳也平仓，平仓后不在开仓，等待下一个信号；


谢谢老师，均线和开仓手数INPUT一下。

技术009

[PEL] 复制代码

input:n1(20,1,1000,1),n2(30,1,1000,1),n3(60,1,1000,1);
input:ss(1,1,100,1);
ma1:"ma.ma1#day"(n1);//调用日线n1周期均线
ma2:ma(c,n2);
ma3:ma(c,n3);


majc:cross(ma2,ma3);
masc:cross(ma3,ma2);

variable:maxprofit=0;//有仓位时最大获利幅度
//开仓
if majc and c>ma1 and holding=0 then
begin
  buy(1,ss,market);
  maxprofit:=0;
end

if masc and c<ma1 and holding=0 then
begin
  buyshort(1,ss,market);
  maxprofit:=0;
end

//平仓
sell(masc,0,market);
sellshort(majc,0,market);


//判断当前持仓状态下的最大盈利
win:=0;
win2:=0;
if holding > 0 and enterbars > 0 then
begin
  win:=(c-enterprice);
  if win>maxprofit then  //记录最大盈利
    maxprofit:=win; 
 
  win2:=(maxprofit-win); //最大盈利后的回调
end

if holding < 0 and enterbars > 0 then
begin
  win:=(enterprice-c);
  if win > maxprofit then  //记录最大盈利
    maxprofit:=win;
 
win2:=(maxprofit-win); //最大盈利后的回调
end


多回调止赢:sell(win2 >= 30*mindiff and maxprofit > 100*mindiff, 0,market);
空回调止赢:sellshort(win2 >= 30*mindiff and maxprofit > 100*mindiff, 0,market);

Mr.Virgo

谢谢老师

Mr.Virgo

老师，再帮加一句开仓后回撤30个点止损。

Mr.Virgo

想把日线换为小时线的是什么参数

技术009

你直接判断win 是否小于30个点就行了。写法和前面类似，你可以尝试自行编写下。

ma1:"ma.ma1#MIN60"(n1);

跨指标调用可以参考这里详细的说明：https://www.weistock.com/docs/PE ... D%E4%BD%9C%E7%AC%A6

Mr.Virgo

技术009 发表于 2022-7-29 13:12
你直接判断win 是否小于30个点就行了。写法和前面类似，你可以尝试自行编写下。

ma1:"ma.ma1#MIN60"(n1) ...

好的，谢谢

Mr.Virgo

老师，还想加一句开仓后带30个点的止损。