为什么开仓条件设为0 只有多没有空，设为1 有时无开仓 后面就有平仓

老伍

duokong: = 0;  //多空开关，1代表只做多，-1代表只做空，0代表多空都可以
手数:=1;   //自行调整
{周期参数：  0:分笔成交、1:1分钟、2:5分钟、3:15分钟、4:30分钟、5:60分钟
6:日、7:周}
{zhouqi: = 1; }

A1:(EMA(CLOSE,1)-EMA(CLOSE,64)),COLORLIGRAY;
AH:=(EMA(H,4)-EMA(CLOSE,64)),COLORGRAY,LINETHICK1;
AL:=EMA(L,4)-EMA(CLOSE,64),COLORGRAY,LINETHICK1;


M:=(H-L)/2 + L;
AM:=(EMA(M,1)-EMA(CLOSE,64)),COLORLIRED,DOTLINE;
AM4:=(EMA(M,4)-EMA(CLOSE,64)),COLORRED,DOTLINE;

J:=(OPEN+L+H+2*C)/5;
JB:=10*(J-REF(J,1))/REF(J,1),COLORSTICK;


A16:=(EMA(C,16)-EMA(C,64)),COLORGRAY;






S1:=IF(C>REF(C,1),V,0);
D1:=IF(C<REF(C,1),V,0);
S:=HHV(S1,4);
D:=HHV(D1,4);



升:=C>REF(C,1);
跌:=C<REF(C,1);
V2:=(IF(升,V,IF(跌,-V,0)));
JV:=JB/V;
MA1:=MA(V2,1),COLORGRAY;
MA2:=MA(V2,2),COLORGRAY,DOTLINE;
MA4:=MA(V2,4),COLORLIGRAY,DOTLINE;


T1:=COUNT(JB>0,4)>=1 OR  COUNT(JB<0,4)>=1;

BTJ1:= A1>AM AND AM>AL AND  AH>REF(AH,1) AND S/D>1.1 AND T1;
BTJ21:= (V2>REF(V2,1) OR JV>REF(JV,1));
BTJ2:= AM>AL AND  AH>REF(AH,1) AND S/D>1.1 AND T1;
BTJ3:= A1>AM4 AND  AH>REF(AH,1) AND S/D>1.1 AND T1;

TJ1:= A1<AM AND AM<AL AND  AH<REF(AH,1) AND D/S<1.1 AND T1;
TJ21:= (V2<REF(V2,1) OR JV<REF(JV,1));
TJ2:= AM<AL AND  AH<REF(AH,1) AND D/S<1.1 AND T1;
TJ3:= A1<AM4 AND  AH<REF(AH,1) AND D/S<1.1 AND T1;




开多条件:= AH>A16 AND A16>REF(A16,1) AND (BTJ1 OR BTJ2 OR (BTJ3 OR BTJ21)) AND duokong>=0 AND HOLDING>=0 ;

多头止损条件1:=  C < REF(L-0.5*H+0.5*L,1);
多头平仓: = (C>(ENTERPRICE + 0.25*M)  OR A1>AH)and A1<AM ;
多头止盈条件1:= C>(ENTERPRICE + 0.5*M) AND (A1<AM OR  V2<REF(V2,1) );
多头止盈条件2:= C>(ENTERPRICE + 0.75*M) AND (A1<AM OR  V2<=REF(V2,1) OR JV<=REF(JV，1));

{平多条件:=T<0.9 AND A1<AM and holding>=0,nodraw;}
平多条件:=(多头止盈条件2 OR 多头止盈条件1 OR 多头平仓  OR 多头止损条件1) and holding>=0,nodraw;







开空条件:=AL<A16 AND A16<REF(A16,1) AND (TJ1 OR TJ2 OR (TJ3 OR TJ21))   and duokong<=0 and  HOLDING<=0 ;



{平空条件:=T>0.9 AND A1>AM and holding<=0,nodraw;}
空头止损条件1:=  C >REF(H+0.5*H-0.5*L,1);
空头平仓: =(C>(ENTERPRICE + 0.25*M)  OR A1<AH) and  A1>AM ;
空头止盈条件1:= C<(ENTERPRICE-0.5*M) AND (A1>AM OR  V2>REF(V2,1));
空头止盈条件2:= C<(ENTERPRICE-0.75*M) AND (A1>AM OR  V2>=REF(V2,1) OR JV>=REF(JV,1)) ;


平空条件:=(空头止盈条件2 OR 空头止盈条件1 OR 空头平仓 OR 空头止损条件1 ) and holding<=0 ,nodraw;



CL:=C-0.5*H+0.5*L;
CH:=C+0.5*H-0.5*L;





开空:buyshort(开空条件 and holding<=0,手数,limitr,CH);
平空:sellshort(平空条件 and holding<0, 手数,limitr,c);

开多:buy(开多条件 and holding>=0, 手数,limitr,CL);
平多:sell(平多条件 and holding>0,手数,limitr,c);




当前持仓:HOLDING,COLORGRAY,LINETHICK0,nodraw;

技术009

你改下你平仓的手数设置。你这里中间可能有没有全平的情况

开空:buyshort(开空条件 and holding<=0,手数,limitr,CH);
平空:sellshort(平空条件 and holding<0, holding,limitr,c);

开多:buy(开多条件 and holding>=0, 手数,limitr,CL);
平多:sell(平多条件 and holding>0,holding,limitr,c);

没有全平时候会导致 无法开反向仓位。