系统里的策略修改问题。

103782

有两个问题：
1、因为系统里面的恒温器策略我想改改隔日平仓，结果怎么都不成功，加了以后就全部都开仓以后不平仓了，看下什么原因？
2、另外我把“可平:=DAYHOLDING-HOLDING”放在IF 语句之前去定义也不行，以为我觉得虽然在开仓语句之前，但系统会循环执行，后面也能执行成功，但是不行。另一方面我也试了，因为系统里的恒温器策略有很多IF条件下的平仓，这里我全部在每个IF条件语句里面加入可平:=DAYHOLDING-HOLDING，好像也不行。麻烦问下，这个问题怎么解决比较好？

//交易系统
IF NOT(CMI) THEN BEGIN {震荡模式}
   IF LOW<=关键价 THEN BEGIN
   可平:=DAYHOLDING-HOLDING;
   震荡平空:SELLSHORT(趋买市开多平空条件 AND 可平<=0,可平,LIMITR,MIN(OPEN,关键价));
   震荡平多:SELL(趋买市开空平多条件 AND 可平>0,可平,LIMITR,CLOSE);
   震荡开多:BUY(趋买市开多平空条件  AND HOLDING=0,手数,LIMITR,CLOSE);
   震荡开空:BUYSHORT(趋买市开空平多条件  AND HOLDING>=0,手数,LIMITR,MIN(OPEN,关键价));

   END

技术006

你是股票还是期货。期货中的HOLDING数量必然会大于等于今仓数量，所以在处理上有一定差异。

103782

技术006 发表于 2022-6-4 12:24
你是股票还是期货。期货中的HOLDING数量必然会大于等于今仓数量，所以在处理上有一定差异。

股票的，帮我改下看看怎么处理，谢谢

技术006

问题1：股票没有空头方向的概念。
问题2：股票的可平，是holding-今仓数量。即可平:=HOLDING-DAYHOLDING;

//交易系统
IF NOT(CMI) THEN BEGIN {震荡模式}
   IF LOW<=关键价 THEN BEGIN
   可平:=HOLDING-DAYHOLDING;
   震荡平多:SELL(趋买市开空平多条件 AND 可平>0,可平,LIMITR,CLOSE);
   震荡开多:BUY(趋买市开多平空条件  AND HOLDING=0,手数,LIMITR,CLOSE);
END

103782

技术006 发表于 2022-6-4 19:41
问题1：股票没有空头方向的概念。
问题2：股票的可平，是holding-今仓数量。即可平:=HOLDING-DAYHOLDING;
...

说明一下：我不是菜鸟，这个代码没用的，你可以自己测试一下。所以我才来论坛提问，因为设计到多个IF条件下的开仓和平仓，所以是不是通过全局变量还是什么方式来解决这个问题？

补充内容 (2022-6-5 01:23):
我一开始就是这么写的，发现错的才来提问的

技术006

这是按照上面2个问题处理后的结果。和你是不是菜鸟没有关系。和看待分析处理问题的方向有关系。

[PEL] 复制代码

//中间变量
INPUT:M(50,5,300,30),N(1.25,0.1,10,0.1),SS(1,1,10000,1),K1(0.5,0.1,1,0.1),K2(0.75,0.1,1,0.1);
VARIABLE:A:=0;//0表示仓位是在趋势模式下下单  1表示在震荡模式下下单
MID :  MA(CLOSE,M);//布林中轨
UPPER:MID + N*STD(CLOSE,M);//布林上轨
LOWER:MID - N*STD(CLOSE,M);//布林下轨
今开:=CALLSTOCK(STKLABEL,VTOPEN,6,0);
CMI:=ABS(CLOSE-REF(CLOSE,29))/(HHV(HIGH,30)-LLV(L,30))*100;//0-100 取值越大，说明趋势越强，CMI<20震荡模式，反之为趋势
关键价:(HIGH+LOW+CLOSE)/3;//关键价的计算，国外常称作中枢价格(PIVOT POINT)
ATR10:=MA(TR,10);
3日均低价:=MA(L,3);
3日均高价:=MA(H,3);
手数:=SS;


//交易条件
IF C<关键价 THEN BEGIN
趋买市开多条件:=C>MAX(今开+K1*ATR10,3日均低价);
趋买市平多条件:=C<MIN(今开-K2*ATR10,3日均高价);
END
    
IF C>关键价 THEN BEGIN
趋卖市开多条件:=C>MAX(今开+K2*ATR10,3日均低价);
趋卖市平多条件:=C<MIN(今开-K1*ATR10,3日均高价);
END
趋势开多条件:=C>UPPER;
趋势平多条件:=C<MID;
震荡多单平仓条件:=C<=ENTERPRICE-3*ATR10;

//交易系统
IF CMI<20 THEN BEGIN {震荡模式}
   IF C<关键价 THEN BEGIN
   可平:=HOLDING-DAYHOLDING;
   趋买市平多:SELL(趋买市平多条件 AND 可平>0,可平,MARKET);
   趋买市开多:BUY(趋买市开多条件 AND HOLDING=0,手数,MARKET);
   A:=1;
   END
   IF C>关键价 THEN BEGIN
   可平:=HOLDING-DAYHOLDING;
   趋卖市平多:SELL(趋卖市平多条件 AND 可平>0,可平,MARKET);
   趋卖市开多:BUY(趋卖市开多条件 AND HOLDING<=0,手数,MARKET);
   A:=1;
   END
END
IF CMI>=20 THEN BEGIN {趋势模式}
IF A:=1 THEN BEGIN //趋势模式下 原震荡模式下 仓位处理
        可平:=HOLDING-DAYHOLDING;
    震荡多单平仓:SELL(震荡多单平仓条件 AND 可平>0,可平,MARKET);
    A:=0;
    END
    
IF A:=0 THEN BEGIN
        可平:=HOLDING-DAYHOLDING;
        趋势平多:SELL(趋势平多条件 AND 可平>0,可平,MARKET);
        趋势开多:BUY(趋势开多条件 AND HOLDING=0,手数,MARKET);
        A:=0;
END
END
//注意先平后开原则

当前持仓:HOLDING,COLORGRAY,LINETHICK0;
今仓:DAYHOLDING;
当前资产:ASSET,NOAXIS,COLORGRAY;//输出当前资产，但不影响坐标最高最低值

103782

技术006 发表于 2022-6-5 09:59
这是按照上面2个问题处理后的结果。和你是不是菜鸟没有关系。和看待分析处理问题的方向有关系。

好的，我也是这么写的，肯定前面的条件写错了，谢谢，也只是试试，这策略蛮有意思 可惜不赚钱