金字塔为什么会在未来显示数据？ - 金字塔软件问题提交 - 金字塔客服中心 - 专业程序化交易软件提供商

//画线思路：找到市场情绪的历史相似点，分“涨、横、跌”三种路径，与当下走势拟合到一起，随着走势的发展，程序将用柱状线标识当下走势在历史数据中的位置。

//选点的时候，注意聚合点定位在盘整走势类型起点，涨起点和跌起点在聚合点之前。盘整走势类型可以作为中枢震荡器使用，以识别当下走势的方向及强弱。

//程序设计了显示交易信号及铃声报警，需要人工选择相似路径后，参数为：1-- 涨；2-- 跌；3--横。

//聚合点:=DATE=160817 AND TIME=1500;

da1:=1180208;time1:=145000;zjl:=5513;djl:=11446;jjl:=5563;

聚合点:=DATE=DA1 AND TIME=TIME1;

涨起点:=DATE=1180112 AND TIME=135500;

跌起点:=DATE=1171214 AND TIME=141000;

近似点:=DATE=1180326 AND TIME=145000;

涨距离:=ZJL;

跌距离:=DJL;

近距离:=JJL;

路径:=1;//参数：1 涨；2 跌；3横；通过手动填写参数选择标注交易信息的路径；

幅度1:=0.5;//手动填写波动幅度

幅度2:=1.5;//手动填写波动幅度

FZ0:=PEAKBARS(c,幅度1,1),COLORWHITE;

GZ0:=TROUGHBARS(c,幅度1,1),COLORWHITE;

//在当前区域最可能的路径上标上买卖信号

涨N:=BARSLAST(涨起点);

跌N:=BARSLAST(跌起点);

横N:=BARSLAST(聚合点);

近N:=BARSLAST(近似点);

涨路径:=REF(C,涨N-近N)-(REF(C,涨N)-REF(C,近N)),COLORRED;

跌路径:=REF(C,跌N-近N)-(REF(C,跌N)-REF(C,近N)),COLORGREEN;

横路径:=REF(C,横N-近N)-(REF(C,横N)-REF(C,近N)),COLORCYAN;

LJN:=IF(路径=1,涨N-近N,IF(路径=2,跌N-近N,横N-近N));

标注位置:=IF(路径=1,涨路径,IF(路径=2,跌路径,横路径));

RFZ:=REF(FZ0,LJN),COLORWHITE,NODRAW;

RGZ:=REF(GZ0,LJN),COLORWHITE,NODRAW;

顶卖:RFZ=0,nodraw;

底买:RGZ=0,nodraw;

DAYO:DATE,NODRAW,COLORWHITE;

TIMEO:TIME,NODRAW,COLORWHITE;

//上涨

AP1:=涨起点;

BP1:=聚合点;

AN1:=BARSLAST(AP1),NODRAW,COLORRED;

BN1:=BARSLAST(BP1),NODRAW,COLORRED;

DN1:AN1-BN1,COLORRED,NODRAW;

RN1:=涨距离;//手动录入DN1值;

//在前点价格位置画当前价格

AC1:=REF(C,AN1);

BC1:=REF(C,BN1);

DD1:=BACKSET(ISLASTBAR,DN1),NODRAW;

DIS1:=AC1-BC1;

DL1:=REFX(DIS1+C,RN1);//RN值为DN的手动录入值

DRAWLINE(AP1,C,BP1,C,0),COLORRED,LINETHICK1,NOTEXT;

DDB1:=COUNT(DD1,BARSLAST(AP1))=0;

CC1:=IF(DDB1,DL1,NULL),COLORRED,DOT,NOTEXT;

DDD1:=COUNT(DD1,BARSLAST(AP1))=1;

//STICKLINE(DDD1,C,REF(CC1,1),1,1),COLORRED;

//在当前价格位置画前点价格

RA1:=REF(C,DN1);

RCC1:if(c>0,RA1-DIS1,drawnull),COLORRED,DOT,NOTEXT;

//下跌

AP2:=跌起点;

BP2:=聚合点;

AN2:=BARSLAST(AP2);

BN2:=BARSLAST(BP2);

DN2:AN2-BN2,COLORGREEN,NODRAW;

RN2:=跌距离;//手动录入DN2值;

//在前点价格位置画当前价格

AC2:=REF(C,AN2);

BC2:=REF(C,BN2);

DD2:=BACKSET(ISLASTBAR,DN2),NODRAW;

DIS2:=AC2-BC2;

DL2:=REFX(DIS2+C,RN2);//RN2值为DN2的手动录入值

DRAWLINE(AP2,C,BP2,C,0),COLORGREEN,LINETHICK1,NOTEXT;

DDB2:=COUNT(DD2,BARSLAST(AP2))=0,COLORGREEN;

CC2:=IF(DDB2,DL2,NULL),COLORGREEN,LINETHICK2,NOTEXT;

DDD2:=COUNT(DD2,BARSLAST(AP2))=1;

//STICKLINE(DDD2,C,REF(CC2,1),1,1),COLORGREEN;

//在当前价格位置画前点价格

RA2:=REF(C,DN2);

RCC2:if(c>0,RA2-DIS2,drawnull),COLORGREEN,DOT,NOTEXT;

//向聚合点映射当前价格

AP3:=聚合点;

BP3:=近似点;

AN3:=BARSLAST(AP3);

BN3:=BARSLAST(BP3);

DN3:ABS(AN3-BN3),COLORWHITE,NODRAW;

RN3:=近距离;//手动录入DN值;

//在前点价格位置画当前价格

AC3:=REF(C,AN3);

BC3:=REF(C,BN3);

DD3:=BACKSET(ISLASTBAR,DN3-1),NODRAW;

DIS3:=AC3-BC3;

DL3:=REFX(DIS3+C,RN3);//RN3值为DN3的手动录入值

DRAWLINE(AP3,C,BP3,C,0),COLORCYAN,LINETHICK1;

DDB3:=COUNT(DD3,BARSLAST(AP3))=0 and an3>0 ;

CC3:IF(DDB3,DL3,NULL),COLORWHITE,LINETHICK2;

DDD3:=COUNT(DD3,BARSLAST(AP3))=1;

STKA:=MAX(C,MAX(RCC1,MAX(RCC2,CC3)));

STKB:=MIN(C,MIN(RCC1,MIN(RCC2,CC3)));

STICKLINE(DDD3 ,REF(STKA,1),REF(STKB,1),1,1,COLOrgray);

//在当前价格位置画前点价格

RA3:=REF(C,DN3);

RCC3:=RA3-DIS3,COLORWHITE,DOT,NOTEXT;

//按照“幅度1”和“幅度2”，在近似点最相似的路径上标注箭头和笑脸...

FFZ1:=PEAKBARS(c,幅度1,1);//到幅度1高点的时间...

GGZ1:=TROUGHBARS(c,幅度1,1);//到幅度1低点的时间...

FFZ2:=PEAKBARS(c,幅度2,1);//到幅度2高点的时间...

GGZ2:=TROUGHBARS(c,幅度2,1);//到幅度2低点的时间...

LJN:=IF(路径=1,涨N-近N,IF(路径=2,跌N-近N,横N-近N));//根据手动修改的“路径”参数，选择近似点到相应的前点的时间...

标注位置:=IF(路径=1,涨路径,IF(路径=2,跌路径,横路径));//根据手动修改的“路径”参数，在近似点之后标出相应路径的位置...

RFZ1:=REF(FFZ1,LJN);//从近似点向前，找到相应路径距波幅1高点的时间

RGZ1:=REF(GGZ1,LJN);

FZ1:=RFZ1=0;//从近似点向前，找到相应路径距波幅1高点的时间为0的点，即将过去高点映射到当下。

GZ1:=RGZ1=0;

RFZ2:=REF(FFZ2,LJN);

RGZ2:=REF(GGZ2,LJN);

FZ2:=RFZ2=0;

GZ2:=RGZ2=0;

DRAWICON(FZ2,标注位置,2);

DRAWICON(GZ2,标注位置,1);

DRAWICON(FZ1,标注位置,5);

DRAWICON(GZ1,标注位置,4);

涨:IF(路径=1,涨路径,NULL),COLORRED;

跌:IF(路径=2,跌路径,NULL),COLORGREEN;

横:IF(路径=3,横路径,NULL),COLORCYAN;

//按照“幅度1”和“幅度2”，在聚合点最相似的路径拐点标注箭头和笑脸...

QLJN:=IF(路径=1,DN1,IF(路径=2,DN2,IF(路径=3,DN3,0)));//根据手动修改的“路径”参数，选择前点到聚合点的时间...

Q标注位置:=IF(路径=1,RCC1,IF(路径=2,RCC2,0));//根据手动修改的“路径”参数，选择前点路径。第三种路径系近似点向聚合点倒推，对应了收盘价，移到下面另起一段计算、标注...

QRFZ1:REF(FFZ1,QLJN);

QRGZ1:REF(GGZ1,QLJN);

QFZ1:=QRFZ1=0;

QGZ1:=QRGZ1=0;

QRFZ2:REF(FFZ2,QLJN);

QRGZ2:REF(GGZ2,QLJN);

QFZ2:=QRFZ2=0;

QGZ2:=QRGZ2=0;

DRAWICON(QFZ2,Q标注位置,2);

DRAWICON(QGZ2,Q标注位置,1);

DRAWICON(QFZ1,Q标注位置,5);

DRAWICON(QGZ1,Q标注位置,4);

LJ3FZ1:=路径=3 AND FFZ1=0 AND COUNT(近似点,BARSLAST(AP3))=0;//在聚合点到近似点（横盘）区间，找出波动幅度为“幅度1”的高点...

LJ3GZ1:=路径=3 AND GGZ1=0 AND COUNT(近似点,BARSLAST(AP3))=0;//在聚合点到近似点（横盘）区间，找出波动幅度为“幅度1”的低点...

LJ3FZ2:=路径=3 AND FFZ2=0 AND COUNT(近似点,BARSLAST(AP3))=0;//在聚合点到近似点（横盘）区间，找出波动幅度为“幅度2”的高点...

LJ3GZ2:=路径=3 AND GGZ2=0 AND COUNT(近似点,BARSLAST(AP3))=0;//在聚合点到近似点（横盘）区间，找出波动幅度为“幅度2”的低点...

DRAWICON(LJ3FZ2,C,2);

DRAWICON(LJ3GZ2,C,1);

DRAWICON(LJ3FZ1,C,5);

DRAWICON(LJ3GZ1,C,4);

DXFZ1:=FFZ1=0 AND BARSLAST(近似点)>=0;//近似点后，找出波动幅度为“幅度1”的高点...

DXGZ1:=GGZ1=0 AND BARSLAST(近似点)>=0;//近似点后，找出波动幅度为“幅度1”的低点...

DXFZ2:=FFZ2=0 AND BARSLAST(近似点)>=0;//近似点后，找出波动幅度为“幅度2”的高点...

DXGZ2:=GGZ2=0 AND BARSLAST(近似点)>=0;//近似点后，找出波动幅度为“幅度2”的低点...

DRAWTEXT(DXFZ2,H,'S'),COLORYELLOW;

DRAWTEXT(DXGZ2,L,'B'),COLORYELLOW;

DRAWTEXT(DXFZ1 AND NOT(DXFZ2),H,'1'),COLORWHITE;

DRAWTEXT(DXGZ1 AND NOT(DXGZ2),L,'0'),COLORWHITE;

BUY1:=FZ1 OR GZ1;

BUY2:=FZ2 OR GZ2;

PLAYSOUND(BUY1,'A');

PLAYSOUND(BUY2,'B');

主题：金字塔为什么会在未来显示数据？