55天海龟看图 - 交易策略发布专区 - 金字塔客服中心 - 专业程序化交易软件提供商

input:N1(55,6,99);
input:N2(20,2,99); //定义变量

LC:=REF(CLOSE,1);
//引用上一周期的收盘价

TR123:=MAX((HIGH - LOW),MAX((HIGH - LC),(LC - LOW)));
//判断，取三个计算公式里面的最大值

ATR:=SMA(TR123,20,1);
//求三十日的平均移动TR123的值

AA:=(HHV(HIGH,N1) - (2 * ATR));
//AA=N1周期最高价-2*ATR

BB:=CROSS(CLOSE,REF(HHV(HIGH,55),1));
//判断收盘价是否上穿上个周期的55周期最高价

SSS:=CROSS(MIN(MA(CLOSE,13),AA),CLOSE);
//判断AA和13周期均线的最小值，是否上穿收盘价

BBB:=BARSLAST(BB);
//上一个BB条件满足到现在的周期数

SSSB:=BARSLAST(SSS);
//上一个SSS条件满足到现在的周期数

B1:=((BBB = 0) AND (REF(SSSB,1) < REF(BBB,1)));
//BBB=0的同时还要上个周期的SSSB小于上个周期的BBB

B1B:=BARSLAST(B1);
//上一个B1条件满足到现在的周期数

B2:=((((BB = 1) AND (B1B < SSSB)) AND (B1B > 0)) AND (COUNT(BB,SSSB) < 3));
//bb=1同时 B1B小于SSB同时B1B大于0同时SSSB个周期内BB成立次数小于3

B2B:=BARSLAST(B2);
//上一个B2条件满足到现在的周期数

B3:=((((BB = 1) AND (B2B < B1B)) AND (COUNT(BB,SSSB) < 4)) AND (COUNT(BB,SSSB) > 2));
//bb=1同时 B2B小于B1B 同时SSSB个周期内BB成立次数小于4大于2

B3B:=BARSLAST(B3);
//上一个B3条件满足到现在的周期数

SS:=CROSS(MAX(AA,MA(CLOSE,13)),CLOSE);
//判断AA和13周期均线的最大值是否上穿收盘骄傲

SS1:=(((SS AND ((B3B < B2B) OR (B2B < B1B))) AND (SSSB > B1B)) AND (COUNT(SS,B2B) < 2));
//ss条件满足同时 B3B小于B2B或者B2B小于B1B 同时 SSSB大于B1B 同时B2B个周期内SS成立次数小于2

SS1B:=BARSLAST(SS1);
//上一个SS1条件满足到现在的周期数

SS2:=((((SS AND (SS1B < SSSB)) AND (B3B < B2B)) AND (SS1B > 0)) AND (COUNT(SS,B2B) < 3));
//ss条件成立同时 SS1B小于SSSB 同时B3B小雨B2B 同时SS1大于0 同时B2B个周期内SS成立次数小于3

SSSS:=(SSS AND (REF(SSSB,1) > REF(B1B,1)));
// SSS条件成立通知上个周期的SSSB大于上个周期的B1B

DRAWICON((B1 = 1),(LOW - 0.1),1);//
DRAWTEXT((B1 = 1),(LOW - 0.25),'买1'),colorFF;
DRAWICON((B2 = 1),(LOW - 0.1),1);
DRAWTEXT((B2 = 1),(LOW - 0.25),'买2'),colorFF;
DRAWICON((B3 = 1),(LOW - 0.1),1);
DRAWTEXT((B3 = 1),(LOW - 0.25),'买3'),colorFF;
DRAWICON((SS1 = 1),(HIGH + 0.1),2);
DRAWTEXT((SS1 = 1),(HIGH + 0.25),'止损1'),colorFF00;
DRAWICON((SS2 = 1),(HIGH + 0.1),2);
DRAWTEXT((SS2 = 1),(HIGH + 0.25),'止损2'),colorFF00;
DRAWICON((SSSS = 1),(HIGH + 0.1),2);
DRAWTEXT((SSSS = 1),(HIGH + 0.25),'快卖'),colorFF00;

尝试着变成交易系统但是写失败了，很多有的，如果是重复了，就删了吧

主题：55天海龟看图