[分享]一个实用的交易策略：3分钟四线趋势交易系统和源码 - 交易策略发布专区 - 金字塔客服中心 - 专业程序化交易软件提供商

3分钟四线趋势的改进

看了有点乱，重编辑一下

//股指期货自动交易程序(3分钟日内四k线趋势交易系统)

//编制:

//日期：2013年3月17日定稿；

{

//加密及期限

drawtextex(1,1,200,800,engincode());

rzb:=strcmp(engincode(),'aaaaaaaaaa');

if rzb<>0 then

begin

drawtextex(1,1,500,500,'程序不能在此计算机上运行');

exit;

end

有效期:1121230,linethick0;

账号:11111,linethick0;

zhh:=strtonum(taccount(1));

if zhh<>账号 then

begin

drawtextex(1,1,500,500,'授权账号不正确，程序无法使用');

exit;

end

if date>有效期 then

begin

drawtextex(1,1,500,500,'已过授权时间，程序无法使用');

exit;

end

if datatype<>17 then

begin

drawtextex(1,1,50,950,'本程序使用3分钟周期，请切换到3分钟周期');

exit;

end

}

//========================================================

//交易控制变量

variable:a1=0;

variable:a2=1;

variable:c1=1;

//**********************************

//交易手数：

tn:=1;

//最大持仓量

cx:=1;

//提前下单量（秒）

xd:=3;

//交易时间区间

p1:=time>091800 and time<150700;

p2:=if(islastbar,dynainfo(207),time);

p3:=time0-timetot0(p2),linethick0;

//********************************

r1:=barslast(date<>ref(date,1));

r2:=ref(o,r1+1);

//********************************

hd:=if(islastbar,3,1);//即时下单加1点的滑点；

hd1:=if(islastbar,3,0.2);//k线走完提前3秒下单加0.2点的滑点；

//********************************

//止损模块应该放到前面，尤其是即时止损并开仓的就必须放到前面。

r20:=enterbars+1;

r21:=ref(hhv(h,r20),1);

r22:=ref(llv(l,r20),1);

r23:=33;

r24:=holding>0 and r21-l>r23 and exitbars>0;

r25:=holding<0 and h-r22>r23 and exitbars>0;

if r24 and p3<=xd and p1 then

begin

sell(holding>0,0,limitr,r21-r23-hd);

end

if r25 and p3<=xd and p1 then

begin

sellshort(holding<0,0,limitr,r22+r23+hd);

end

//********************************

//日盈利超过8000元/手时（收盘时的收益计算），停止交易210个周期。

//在停止交易的时间里如果收盘价离开开盘价30点则恢复交易。

r12:=asset-ref(asset,90);

r13:=valuewhen(r1=0,r12);

if r13>8000*cx and a2>0 then

begin

a1:=barpos;

a2:=-1;

end

r16:=barpos-a1>=210;

if r16 and r1<2 then a2:=1;

if abs(c-r2)>30 then c1:=-1;

r17:=r16 or c1<0;

//********************************

sqsxd:=count(c>ref(c,1),3)=3 and count(c>=o,4)=4,linethick0;

sqsxk:=count(c<ref(c,1),3)=3 and count(c<=o,4)=4;

if sqsxd and r17 and p1 and p3<=xd then

begin

sellshort(holding<0,tn,limitr,c+hd1);

buy(holding=0,tn,limitr,c+hd1);

end

if sqsxk and r17 and p1 and p3<=xd then

begin

sell(holding>0,tn,limitr,c-hd1);

buyshort(holding=0,tn,limitr,c-hd1);

end

//********************************

//收盘前清仓

if p2>=151200 then

begin

sellshort(holding<0,0,limitr,c+hd1);

sell(holding>0,0,limitr,c-hd1);

c1:=1;

end

//*************************************

交易总数:totaltrade,colorwhite,linethick0;

盈亏:asset-1000000,colorred,linethick1,noaxis;

日盈亏:asset-ref(asset,r1+1),noaxis,colorred,linethick0;

持仓:holding,colorwhite,linethick0;

rr1:=barslast(month<>ref(month,1));

月盈利:asset-ref(asset,rr1+1),linethick0;

1.对于初学者来说这是一个很好的模板。

2.不要太在意结果，重要的是思路。

[此贴子已经被作者于2013-3-17 10:11:34编辑过]

为什么要提前下单呢？

咋么没有看到源码

这是我比较早发表的一个策略，说实话，这是一个比较粗的策略，只是拿出来玩玩而已。但就是在个比较粗的策略，如果你用2分钟周期，4分钟周期和8分钟周期各交易1手，那么结果就是这样

此主题相关图片如下：qq截图20140411211305.png

实际跑出来的结果比图表上的还要好（因为我现在k线走完不要考虑滑点了，并且连手续费都不要考虑，这个程序考虑了1跳和0.00275%%的手续费）。

你好：上图的资金曲线是显示在日线上的，而模型是3分钟的，请教是如何实现的，能分享代码吗？谢谢！！！

以下是引用wzywzy292在2014/4/12 20:18:29的发言：
你好：上图的资金曲线是显示在日线上的，而模型是3分钟的，请教是如何实现的，能分享代码吗？谢谢！！！

没有问题，对于日内交易我都只考察一天的盈亏情况，而不管中间的具体交易。下面是代码

//股指期货自动交易程序(系统测试)

//编制：

//日期：

//修改记录：

//********************************

r1:=barslast(date<>ref(date,1));

r2:=ref(o,r1);

//partline(r1>0,r2);

//********************************

rr1:=stkindiex('if00','qq25.盈亏',0,22,70,0);

rr2:=stkindiex('if00','qq25.盈亏',0,22,75,0);

rr3:=stkindiex('if00','qq25.盈亏',0,22,80,0);

rr4:=stkindiex('if00','qq25.盈亏',0,22,85,0);

rr5:=stkindiex('if00','qq25.盈亏',0,22,90,0);

rr6:=stkindiex('if00','qq25.盈亏',0,22,95,0);

rr7:=stkindiex('if00','qq25.盈亏',0,22,100,0);

rr8:=stkindiex('if00','qq25.盈亏',0,22,105,0);

rr9:=stkindiex('if00','qq25.盈亏',0,22,110,0);

rr10:=stkindiex('if00','qq25.盈亏',0,22,115,0);

rr11:=stkindiex('if00','qq25.盈亏',0,22,120,0);

rr12:=stkindiex('if00','qq25.盈亏',0,22,125,0);

rr13:=stkindiex('if00','qq25.盈亏',0,22,130,0);

rr14:=stkindiex('if00','qq25.盈亏',0,22,135,0);

rr15:=stkindiex('if00','qq25.盈亏',0,22,140,0);

rr16:=stkindiex('if00','qq25.盈亏',0,22,145,0);

rr17:=stkindiex('if00','qq25.盈亏',0,22,150,0);

rr18:=stkindiex('if00','qq25.盈亏',0,22,155,0);

rr19:=stkindiex('if00','qq25.盈亏',0,22,160,0);

rr20:=stkindiex('if00','qq25.盈亏',0,22,165,0);

r15:=rr1+rr2+rr3+rr4+rr5+rr6+rr7+rr8+rr9+rr10+rr11+rr12+rr13+rr14+rr15+rr16+rr17

+rr18+rr19+rr20;

//********************************

总盈利:r15,colorred,linethick1,noaxis;

variable:hc=0;

回撤:=hhv(r15,3000)-r15,linethick0,coloryellow;

if 回撤>hc then hc:=回撤；

最大回撤:hc,linethick0,coloryellow;

日盈亏:r15-ref(r15,1),linethick0;

总盈利/最大回撤:r15/回撤,colorwhite,linethick0;

r20:=if(r15>ref(r15,1),1,0);

r22:=if(r15<>ref(r15,1),1,0);

r21:=100*sum(r20,0)/(sum(r22,0));

胜率:r21,linethick0,colorwhite;

r30:=if(r15>ref(r15,1),r15-ref(r15,1),0);

r31:=sum(r30,0);

r32:=if(r15>ref(r15,1),1,0);

r33:=sum(r32,0);

平均盈利:=r31/r33,linethick0,colorwhite;

r40:=if(r15<ref(r15,1),r15-ref(r15,1),0);

r41:=sum(r40,0);

r42:=if(r15<ref(r15,1),1,0);

r43:=sum(r42,0);

平均亏损:=r41/r43,linethick0,colorwhite;

r50:=平均盈利/(-1*平均亏损),linethick0;

平均盈利/平均亏损:r50,linethick0,colorwhite;

总盈利/总亏损:r31/(-1*r41),colorwhite,linethick0;

模型综合性能:胜率*r50,linethick0,colorwhite;

主题：[分享]一个实用的交易策略：3分钟四线趋势交易系统和源码