主题：[公告]求购SARPB抛物转向（澎博）源码

找彭博的问问不就成了

澎博，回复，函数已经分装，没有源码了，估计一听我要用金字塔来搞，不愿意给了。现在只有交易开拓者有SAR的源码

金字塔能不能搞一个出来啊。方便我们可以改改，弄出新的东西出来，或者按SARPB抛物转向，改一个，他那个抛物线确实不错，整体比较舒服。金字塔的大能们，改一个出来吧

 Params
 Numeric AfStep(0.02);
 Numeric AfLimit(0.2);
 NumericRef oParClose;
 NumericRef oParOpen;
 NumericRef oPosition;
 NumericRef oTransition;
Vars
 NumericSeries Af(0); 
 NumericSeries ParOpen(0);
 NumericSeries Position(0); 
 NumericSeries HHValue(0);
 NumericSeries LLValue(0);
Begin
 If (CurrentBar == 0)
 {
  Position = 1 ;
  oTransition = 1 ;
  Af = AfStep ;
  HHValue = High ;
  LLValue = Low ;  
  oParClose = LLValue ;
  ParOpen = oParClose + Af * ( HHValue - oParClose) ;
  If (ParOpen > Low)
  {
   ParOpen = Low ;
  }
 }Else
 { 
  oTransition = 0 ; 
  If (High > HHValue[1])
  {
   HHValue = High;
  }Else
  {
   HHValue = HHValue[1];
  }
  
  If (Low < LLValue[1])
  {
   LLValue = Low;
  }Else
  {
   LLValue = LLValue[1];
  }
  
  If ( Position[1] == 1)
  {
   If ( Low <= ParOpen[1])
   {
    Position = -1 ;
    oTransition = -1 ;    
    oParClose = HHValue ;
    HHValue = High ;
    LLValue  = Low ;
 
    Af = AfStep ;
    ParOpen = oParClose + Af * ( LLValue - oParClose ) ;
     
    If (ParOpen < High)
    {
     ParOpen = High ;
    }
    
    If (ParOpen < High[1])
    {
     ParOpen = High[1] ;
    }
   }Else
   {
    Position = Position[1];
    oParClose = ParOpen[1] ;     
    If (HHValue > HHValue[1] and Af[1] < AfLimit )
    {
     If(Af[1]+AfStep > AfLimit)
     {
      Af = AfLimit ;
     }Else
     {
      Af = Af[1]+AfStep;
     }    
     
    }Else
    {
     Af = Af[1];
    } 
    ParOpen = oParClose + Af * ( HHValue - oParClose ) ;    
 
    If (ParOpen > Low)
    {
     ParOpen = Low ;
    }
    
    If (ParOpen > Low[1])
    {
     ParOpen = Low[1];
    }
   }
  }Else
  {
   If (High >= ParOpen[1])
   {
    Position = 1 ;
    oTransition = 1 ;
    
    oParClose = LLValue ;
    HHValue = High ;
    LLValue  = Low ;
    
    Af = AfStep ;
    ParOpen = oParClose + Af * ( HHValue - oParClose) ;
    If (ParOpen > Low)
    {
     ParOpen = Low ;
    }
    
    If (ParOpen > Low[1])
    {
     ParOpen = Low[1];
    }
   }Else
   {
    Position = Position[1];
    oParClose = ParOpen[1];
     
    If (LLValue < LLValue[1] And Af[1] < AfLimit )
    {
     If(Af[1]+AfStep > AfLimit)
     {
      Af = AfLimit ;
     }Else
     {
      Af = Af[1]+AfStep;
     }
    }Else
    {
     Af = Af[1];
    }
    ParOpen = oParClose + Af * ( LLValue - oParClose ) ;
 
    If (ParOpen < High)
    {
     ParOpen = High ;
    }
    
    If (ParOpen < High[1])
    {
     ParOpen = High[1] ;
    }
   }
  } 
 } 
 
 oParOpen = ParOpen;
 oPosition = Position;
 Return True;
End

难道就只知道看第一页的标题，连搜索功能都不会用的吗？

http://www.weistock.com/bbs/dispbbs.asp?BoardID=10&ID=3437&replyID=&skin=1

找我吧，看在3000大洋的份上。