主题：[原创]闲来无聊，发布一个本人常用的模版： 移动止损模版_leevolvo版

//该模版用于历史评测，不用于实盘交易。
//该模版的亮点在于模块化和扩展性

//理解模版精华后，各种思路可在模版里随便添加、删除、扩展等
variable:zs=c,hl=c;//声明全局变量zs、hl
ma5:=ma(c,5);
ma20:=ma(c,20);
atr:=ma(h-l,20);//市场平均波动幅度
buycond:=cross(ma5,ma20);//平空开多条件
sellcond:=cross(ma20,ma5);//平多开空条件

if holding>0 then begin
 多止损:zs;
 if l<zs then sell(1,1,limitr,min(o,zs)-mindiff);
 else if sellcond then sell(1,1,limitr,c);
end

if holding<0 then begin
 空止损:zs;
 if h>zs then sellshort(1,1,limitr,max(o,zs)+mindiff);
 else if buycond then sellshort(1,1,limitr,c);
end

if holding=0 and buycond then begin//多头开仓
 buy(1,1,limitr,c);
 zs:=c-2*atr;
 hl:=c;//hl开仓后的最有利价位，刚买入时，最有利价位为开仓价
end

if holding=0 and sellcond then begin//空头开仓
 buyshort(1,1,limitr,c);
 zs:=c+2*atr;
 hl:=c;
end

if holding>0 and enterbars>0 and h>hl then begin//最高价抬升，止损位相应地抬升
 hl:=h;
 zs:=hl-2*atr;
end

if holding<0 and enterbars>0 and l<hl then begin//最低价下降，止损位相应地下移
 hl:=l;
 zs:=l+2*atr;
end

请问楼主，把它直接用于实盘行吗？

请问版主，如果把它直接用在实盘里可以吗？您说是您经常用的！那适用在多少分钟图里比较准备长久一点呢~？谢谢，请把你的经验和大家分享一下吧！

这是模板。不是实际可行的交易策略

且以上模板 止损是盘中触发即执行，而下单是收盘确认信号才执行，所以，用于实盘还需要做点改动

当然，也只要在你确认自己的模型确实可行要实盘交易了再去改动。做历史回撤足够了

强帖留名，支持楼主！