主题：【悬赏】编写IF日内突破交易规则

INPUT:NMIN(39,10,60,10);                                          //设置参数时

VARIABLE:FLAG_D=0,FLAG_K=0;                                //控制多单和空单

VARIABLE:STOP_P=0; //用于变动止损

CYC:=BARSLAST(DATE>REF(DATE,1))+1;                            //统计日内K线数

HH:VALUEWHEN(TIME<=91500+NMIN*100,HHV(H,CYC));                           {在从开盘到设定时间(默认参数开盘39分)内保存当天最高价}

LL:VALUEWHEN(TIME<=91500+NMIN*100,LLV(L,CYC));                      {在从开盘到设定时间(默认参数开盘39分)内保存当天最低价}

IF H>STOP_P AND HOLDING<0 THEN SELLSHORT(1,1,LIMITR,MAX(O,STOP_P)+20*MINDIFF);
IF L<LL*0.97 AND HOLDING<0 THEN SELLSHORT(1,1,LIMITR,LL*0.97+50*MINDIFF);

IF L<STOP_P AND HOLDING>0 THEN SELL(1,1,LIMITR,MIN(O,STOP_P)-20*MINDIFF);
IF H>HH*1.03 AND HOLDING>0 THEN SELL(1,1,LIMITR,HH*1.03-50*MINDIFF);

IF TIME=151000 THEN //收盘平仓，并重置全局变量
BEGIN
     SELLSHORT(HOLDING<0,1,LIMITR,OPEN+20*MINDIFF);
     SELL(HOLDING>0,1,LIMITR,OPEN-20*MINDIFF);
     FLAG_D:=0;
     FLAG_k:=0;
END

IF H>HH AND HOLDING=0 AND FLAG_D=0 AND TIME<151000 THEN //开多单
BEGIN
     FLAG_D:=1;
     BUY(1,1,LIMITR,HH+20*MINDIFF);
     STOP_P:=MAX(LL,HH-50*MINDIFF);
     IF FLAG_K=0 THEN STOP_P:=MAX(LL,HH-50*MINDIFF);//当天第一笔交易，未回落50个跳动点就已突破LL，则立马止损反手做空
END

IF L<LL AND HOLDING=0 AND FLAG_K=0 AND TIME<151000 THEN //开空单
BEGIN
     FLAG_K:=1;
     BUYSHORT(1,1,LIMITR,LL-20*MINDIFF);
     STOP_P:=LL+50*MINDIFF;
     IF FLAG_D=0 THEN STOP_P:=MIN(HH,LL+50*MINDIFF);//功能同上
END

IF HOLDING>0 AND H>HH+50*MINDIFF THEN STOP_P:=HH+4*MINDIFF; //重置止损位

IF HOLDING<0 AND L<LL-50*MINDIFF THEN STOP_P:=LL-4*MINDIFF;//重置止损位

前面有奖5个金币了~

我再也一个是否也可以奖5个金币？

顶。顶