主题：为什么这个在套利交易下不开仓?

 之前回复有误，因此重新整理回复下。

软件里面建立的套利品种无法利用程序化去直接监控那个套利品种并交易。比如你品种a 和b构成的套利品种c，你无法直接对c品种程序化。 你只能在代码里面按照套利的操作去分别对a和b下单 ，比如a开多 b开空 相当于一个套利c的开多操作了。所以你原先的代码监控套利品种是无法下单的。

我简单参照你原先思路做一个范例：

//*****************************
账户:'1000';
套利品种1:'rb00';
套利品种2:'ag00';
//*****************************

JC:"rb00$CLOSE"-"ag00$CLOSE";


MA5:MA(JC,5);
MA10:MA(JC,10);

CONDBUY:=CROSS(MA5,MA10);
CONDSELL:=CROSS(MA10,MA5);

tbuyhd1:TBUYHOLDINGEX(账户，套利品种1，2);//品种1多头持仓
tsellhd1:TSellHOLDINGEX(账户，套利品种1，2);//品种1空头持仓

tbuyhd2:TBUYHOLDINGEX(账户，套利品种2，2);
tsellhd2:TsellHOLDINGEX(账户，套利品种2，2);



if CONDBUY  and tsellhd1>0 and tbuyhd1>0 then  //tsellhd1>0  tbuyhd1>0 分别 表示品种1有空头持仓，品种2有多头持仓 
BEGIN
tsellshort(1,0,Mkt,0,0,账户,套利品种2),ORDERQUEUE;
tsell(1,0,Mkt,0,0,账户,套利品种1),ORDERQUEUE;//这2个相当于套利的平空

tbuy(1,1,Mkt,0,0,账户,套利品种2),ORDERQUEUE;
tbuyshort(1,1,Mkt,0,0,账户,套利品种1),ORDERQUEUE; //这2个相当于套利开多
end

后续代码可以仿照这里完善下。

请注意 引号  "RB00$CLOSE" ，单引号是错误方式。

只是运行完成说明信号没有触发。

有差异往往只是时效导致的，数据都是一样但是引用过来时候无法保证一定能同步。

a2:"rb10$dynainfo(19)";
a3:"rb01%dynainfo(18)";

你上面这个

1.是 $ 不是 %号

2.dynainfo(18) 这种动态函数无法通过上面方式引用的。如果真要调用这个动态函数，因为需要指定品种因此建议考虑其他引用方式如stkind函数

 如果你这个条件不好触发。 你最好调整下下单条件

我本地出于调试目的，修改了下单条件，用均价金叉死叉 不一定能保证触发

CONDBUY:=CROSS(MA5,MA10);
CONDSELL:=CROSS(MA10,MA5);

改成了

CONDBUY:=JC>300;
CONDSELL:=JC<300;

并且为了测试下面这段，我直接手工先下了一组套利单子，这样 保证tbuyhd1>0 and tsellhd1 能触发。

if CONDBUY  and tbuyhd1>0 and tsellhd1>0   then BEGIN

tsellshort(1,0,Mkt,0,0,''，stock2),ORDERQUEUE;
 tsell (1,0,Mkt,0,0,''，stock1),ORDERQUEUE;
tbuy(1,1,Mkt,0,0,''，stock1),ORDERQUEUE;
tbuyshort (1,1,Mkt,0,0,''，stock2),ORDERQUEUE;
end

我重新给你整理个案例吧。

完整范例，本地已经测试。其中账号和品种等数据请自行替换下。

//*****************************
账户:'';//自行替换本地的测试账号
套利品种1:='rb00';
套利品种2:='ag00';
//*****************************

JC:"rb00$CLOSE"-"ag00$CLOSE";


MA5:MA(JC,5);
MA10:MA(JC,10);

CONDBUY:JC>702;//价差条件自行重新合理设置下
CONDSELL:jc<500;

tbuyhd1:TBUYHOLDINGEX(账户，套利品种1，2);
tsellhd1:TSellHOLDINGEX(账户，套利品种1，2);

tbuyhd2:TBUYHOLDINGEX(账户，套利品种2，2);
tsellhd2:TsellHOLDINGEX(账户，套利品种2，2);



if CONDBUY  and tsellhd1>0 and tbuyhd2>0 then  //tsellhd1>0  tbuyhd1>0 分别 表示品种1是空头，品种2是多头，相当于一个套利品种的空头 
BEGIN
tsellshort(1,0,Mkt,0,0,账户,套利品种1),ORDERQUEUE; //相当于套利的平空
tsell(1,0,Mkt,0,0,账户,套利品种2),ORDERQUEUE;

tbuy(1,1,Mkt,0,0,账户,套利品种1),ORDERQUEUE;//相当于套利开多
tbuyshort(1,1,Mkt,0,0,账户,套利品种2),ORDERQUEUE;  
end

if CONDSELL and tbuyhd1>0 and tsellhd2>0 then
BEGIN
tsellshort(1,0,Mkt,0,0,账户,套利品种2),ORDERQUEUE;
tsell(1,0,Mkt,0,0,账户,套利品种1),ORDERQUEUE;//相当于套利的平多

tbuyshort(1,1,Mkt,0,0,账户,套利品种1),ORDERQUEUE;
tbuy(1,1,Mkt,0,0,账户,套利品种2),ORDERQUEUE;//相当于套利开空
end


if   CONDBUY and  ((tbuyhd1=0 or tsellhd2=0) and  (tbuyhd2=0 or tsellhd1=0)) then
BEGIN
tbuy(1,1,Mkt,0,0,账户,套利品种1),ORDERQUEUE;//相当于套利开多
tbuyshort(1,1,Mkt,0,0,账户,套利品种2),ORDERQUEUE;
end

if CONDSELL and ((tbuyhd1=0 or tsellhd2=0) and  (tbuyhd2=0 or tsellhd1=0)) then
BEGIN
tbuyshort(1,1,Mkt,0,0,账户,套利品种1);
tbuy(1,1,Mkt,0,0,账户,套利品种2);//相当于套利开空
end