帮帮忙呀，实在无法解决该问题！ - 公式模型编写问题提交 - 金字塔客服中心 - 专业程序化交易软件提供商

取以前15根1分钟K线的最高价和最低价为上轨下轨，

当时间大于9点30分时，

如果MA1大于MA2，且最高价突破上轨，开多

如果MA2大于MA1，且最低价跌破下轨，开空。

这个策略这样写

t1:=time>093000 and time<145000

rh:=ref(hhv(h,15),1);

rL:=ref(llv(L,15),1);

ma10:=ma(c,10);

ma20:=ma(c,20);

if t1 and h>rh and ma10>ma20 then

begin

sellshort(holding<0,0,limitr,rh-0.2);

buy(holding=0,1,limitr,rh-0.2);

end

if t1 and l<rL and ma10<ma20 then

begin

sell(holding>0,0,limitr,rL+0.2);

buyshort(holding=0,1,limitr,rL+0.2);

end

if time>145000 then

begin

sell(holding>0,0,limitr,c);

sellshort(holding<0,0,limitr,c);

end

------------------------------------------

以上是你要的程序，但是你这是一种自欺欺人的做法，你的交易结果是不可能达到这个程序的测试结果的，也就是说如果怎么干你的实盘结果和你的测试结果就没有任何关系。

那么按你的意思也应该写成这样

t1:=time>093000 and time<145000

rh:=ref(hhv(h,15),1);

rL:=ref(llv(L,15),1);

ma10:=ma(c,10);

ma20:=ma(c,20);

if t1 and h>=rh and ma10>ma20 then

begin

sellshort(holding<0,0,limitr,rh+0.4);

buy(holding=0,1,limitr,rh+0.4);

end

if t1 and l<=rL and ma10<ma20 then

begin

sell(holding>0,0,limitr,rL-0.4);

buyshort(holding=0,1,limitr,rL-0.4);

end

if time>145000 then

begin

sell(holding>0,0,limitr,c-0.2);

sellshort(holding<0,0,limitr,c+0.2);

end

----------------------------------------------------------------

这样写也有问题，可能会出现没有成交价格的问题所以按你的策略意思应该这样写；

t1:=time>093000 and time<145000

rh:=ref(hhv(h,15),1);

rL:=ref(llv(L,15),1);

ma10:=ma(c,10);

ma20:=ma(c,20);

if t1 and h>=rh and ma10>ma20 then

begin

sellshort(holding<0,0,limitr,max(rh,o)+0.4);

buy(holding=0,1,limitr,max(rh,o)+0.4);

end

if t1 and l<=rL and ma10<ma20 then

begin

sell(holding>0,0,limitr,min(rL,o)-0.4);

buyshort(holding=0,1,limitr,min(rL,o)-0.4);

end

if time>145000 then

begin

sell(holding>0,0,limitr,c-0.2);

sellshort(holding<0,0,limitr,c+0.2);

end

-------------------------------------------------------

这样的写法其实还是有问题的，会到致你的测试信号和实盘信号有差别（由于这个程序程序的特例差别不是太大）。也就是说你这个小小的程序还含有未来数据。这个你自己琢磨吧。

主题：帮帮忙呀，实在无法解决该问题！