公式模型编写问题提交-关于MACD的顶底背离金字塔客服中心 - 专业程序化交易软件提供商

代码如下：

DIFF : EMA(CLOSE,12) - EMA(CLOSE,26);
DEA : EMA(DIFF,9);
MACD : 2*(DIFF-DEA), COLORSTICK;

//DIFF底背离:

//拐点到当前的周期数
BottumPointCount := BARSLAST( ( DIFF > REF(DIFF, 1) ) AND ( REF(DIFF, 2) > REF(DIFF, 1) ) );

//拐点最低价
BottumPointPrice := REF(LOW, BottumPointCount);

//拐点DIFF值
BottumPointDIFF := REF(DIFF, 1);

//周期内DIFF最小值
DIFFMin := LLV(DIFF, BottumPointCount + Term);

//DIFF最小值到当前的周期数
DIFFMinCount := LLVBARS(DIFF, BottumPointCount + Term);

//MACD最小值时的最低价
DIFFMinPrice := REF(LOW, DIFFMinCount);

//若周期内有小于拐点的DIFF且股价高于拐点最低价
BottumFlag : DIFFMinCount > BottumPointCount
AND DIFFMin < BottumPointDIFF
AND DIFFMinPrice > BottumPointPrice
AND DIFF > REF(DIFF, 1)
AND REF(DIFF, 2) > REF(DIFF, 1), COLORGREEN;

//DIFF顶背离:

//拐点到当前的周期数
TopPointCount := BARSLAST( ( DIFF < REF(DIFF, 1) ) AND ( REF(DIFF, 1) > REF(DIFF, 2) ) );

//拐点最高价
TopPointPrice := REF(HIGH, TopPointCount);

//拐点DIFF值
TopPointDIFF := REF(DIFF, 1);

//周期内DIFF最D大值
DIFFMax := HHV(DIFF, TopPointCount + Term);

//DIFF最大值到当前的周期数
DIFFMaxCount := HHVBARS(DIFF, TopPointCount + Term);

//DIFF最大值时的最高价
DIFFMaxPrice := REF(HIGH, DIFFMaxCount);

//若周期内有大于拐点的MACD，且股价低于拐点价，且当前点为拐点
TopFlag : DIFFMaxCount > TopPointCount
AND DIFFMax > TopPointDIFF
AND DIFFMaxPrice < TopPointPrice
AND DIFF < REF(DIFF, 1)
AND REF(DIFF, 1) > REF(DIFF, 2), COLORYELLOW;

其中，周期Term：缺省30，最小10，最大60，步长为2

[此贴子已经被作者于2016/3/25 10:59:52编辑过]

DIFFMin := LLV(DIFF, BottumPointCount + Term);

这句的目的是，找到此拐点到前term周期内的diff最小值，若最小值不为此拐点，再去判断拥有diff最小值的这根K线的LOW与拐点的LOW是否形成底背离。

DIFFMin := ref(LLV(DIFF, Term),bottumpointcount);

您说的这部分我明白了。

1.意思是以拐点之后的一根k线定义为拐点？

这个并不是说把拐点后的一根K线定义成拐点，而是说，在逐k线模式下，必须走完了拐点后的一根k线，才能确定这根点是拐点。

思路是：先找到diff的拐点（右边），再找到从拐点算起一定周期（term）内的diff最小值（左边），判断这两个值之间的价格最小值，若左边的最小值比右边的最小值大，则形成底背离。

老师您看这样是合理的吗？

1.从找diff的拐点，去对比最低价，变成寻找价格的拐点，去对比diff值。

2.不仅需要寻找周期内价格最低点和当前拐点是否有背离，还要去寻找周期内每一个价格最低点的拐点和当前拐点是否有背离，这个循环应该加在哪？

另外，回复怎么插入图片啊？我上一张回复是有图片的，没显示，我是添加附件进去的。