- 金字塔客服中心 - 专业程序化交易软件提供商 (http://weistock.com/bbs/index.asp)
-- 公式模型编写问题提交 (http://weistock.com/bbs/list.asp?boardid=4)
---- [求助]不知道为什么出错 (http://weistock.com/bbs/dispbbs.asp?boardid=4&id=76015)
-- 发布时间：2015/3/2 9:43:20
-- [求助]不知道为什么出错
此主题相关图片如下：qq图片20150302093754.jpg
//声明参数
INPUT : T20(30,15,30,1) ;
INPUT : T10(13,10,20,1);
INPUT : ATRLEN(20,15,30,1) ;
INPUT : m(0.5,0.02,0.5,0.01);
INPUT : x(2,1,3,0.01);
//声明变量
NT := 1 ; //调试信息带时间戳
BUYORDERTHISBAR := 0 ; //当前BAR有过交易
VARIABLE : _DEBUG = 1 ; //是否输出前台交易指令
VARIABLE : _TDEBUG = 1 ; //是否输出后台交易指令
VARIABLE : _DEBUGOUT = 0 ; //是否输出后台交易的调试信息
VARIABLE : MYENTRYPRICE =0 ; //开仓价格
VARIABLE : MYEXITPRICE =0 ; //平仓价格
VARIABLE : TURTLEUNITS=0 ; //交易单位
VARIABLE : POSITION=0 ; //仓位状态
//0表示没有仓位，1表示持有多头， -1表示持有空头
VARIABLE : T20HI=CLOSE ; //20周期的高点
VARIABLE : T20LO=CLOSE ; //20周期的低点
VARIABLE : T10HI=CLOSE ; //10周期的高点
VARIABLE : T10LO=CLOSE ; //10周期的低点
VARIABLE : POSNUM=0 ; //仓位
VARIABLE: multi=1;
VARIABLE: maxset=0;
VARIABLE: minset=0;
marginratio:=10/100;//保证金比例
//准备需要计算的变量
T20HI:= REF(HHV(H,T20),1) ;
T20LO:= REF(LLV(L,T20),1) ;
T10HI:= REF(HHV(H,T10),1) ;
T10LO:= REF(LLV(L,T10),1) ;
//开始执行时 初始化数据
IF BARPOS=1 THEN BEGIN
maxset:=ASSET;
minset:=asset;
multi:=1;
END //IF
AVGTR := REF(MA(TR,ATRLEN),1) ;
A:=ceiling(AVGTR)* MULTIPLIER*X ;
//POSNUM:=if(FLOOR (ASSET*multi*0.02/A)=0,1,FLOOR (ASSET*multi*0.02/A));//仓位
//POSNUM:=min(FLOOR (ASSET/(C*multiplier*marginratio*4)),POSNUM);//仓位
if BARPOS<ATRLEN+5 then exit;
WARNING_DISABLE:2;
//POSNUM: if(FLOOR (ASSET*0.02/A)=0,1,FLOOR (ASSET*0.02/A)),noaxis;//仓位
//POSNUM:1,noaxis;
if holding=0 then BEGIN
//最大资产
if asset>maxset then BEGIN
maxset:=asset;
minset:=asset;
multi:=1;
end
//开仓手数
POSNUM:=INTPART(ASSET*m/a);//仓位
end
//此处作为临时输出结果
{仓位:posnum,NOAXIS;
最大资金: maxset,NOAXIS;
当前资金: minset,NOAXIS;
比例: MULTI,NOAXIS;}
//如果当前是没有持仓的状态
IF POSITION=0 AND BARPOS>T20 AND H>L THEN BEGIN
//建立多头进场条件
LONG := H > T20HI ;
//多头进场
IF LONG THEN BEGIN
MYENTRYPRICE := IF(OPEN>T20HI+MINDIFF ,OPEN ,T20HI+MINDIFF ) ;
BUY( _DEBUG,POSNUM,LIMITR,MYENTRYPRICE);
POSITION := 1 ;
TURTLEUNITS := 1 ;
N := AVGTR ;
BUYORDERTHISBAR := 1;
END //IF
//建立空头进场条件
SHORT := L < T20LO ;
//空头进场
IF SHORT AND POSITION=0 THEN BEGIN
MYENTRYPRICE := IF(OPEN<T20LO-MINDIFF ,OPEN ,T20LO-MINDIFF ) ;
BUYSHORT( _DEBUG,POSNUM,LIMITR,MYENTRYPRICE);
POSITION := -1 ;
TURTLEUNITS := 1 ;
N := AVGTR ;
BUYORDERTHISBAR := 1;
END
//不要跳转，让程序检查同一根K线是否可以加仓
//GOTO CONTINUELINE ;
END //IF
//如果当前持有多头仓位的状态
IF POSITION=1 AND BARPOS>T20 AND H>L THEN BEGIN
//多头加仓条件
WHILE (HIGH>MYENTRYPRICE+N) AND TURTLEUNITS>4 DO BEGIN
MYENTRYPRICE := IF(OPEN>MYENTRYPRICE+N ,OPEN ,MYENTRYPRICE+N ) ;
MYENTRYPRICE := CEILING(MYENTRYPRICE/MINDIFF)*MINDIFF ;
BUY( _DEBUG, POSNUM, LIMITR, MYENTRYPRICE);
TURTLEUNITS := TURTLEUNITS+1 ;
BUYORDERTHISBAR := 1;
END //WHILE
//建立多头离场条件
LONGX1 := (LOW < T10LO) ;
IF LONGX1 AND BUYORDERTHISBAR=0 THEN BEGIN
MYEXITPRICE := IF(OPEN<T10LO-MINDIFF ,OPEN ,T10LO-MINDIFF ) ;
SELL( _DEBUG ,0,LIMITR,MYEXITPRICE);
POSITION := 0 ;
TURTLEUNITS := 0 ;
END
//建立多头止损条件
LONGX2 := (LOW< MYENTRYPRICE -X*N) ;
IF LONGX2 AND POSITION=1 AND BUYORDERTHISBAR=0 THEN BEGIN
MYEXITPRICE := IF(OPEN<MYENTRYPRICE-N ,OPEN ,MYENTRYPRICE-N ) ;
MYEXITPRICE := FLOOR(MYEXITPRICE/MINDIFF)*MINDIFF ;
SELL( _DEBUG ,0,LIMITR,MYEXITPRICE);
POSITION := 0 ;
TURTLEUNITS := 0 ;
END
GOTO CONTINUELINE ;
END //IF
//如果当前持有空头仓位的状态
IF POSITION = -1 AND BARPOS>T20 AND H>L THEN BEGIN
//空头加仓条件
WHILE (LOW<MYENTRYPRICE-N) AND TURTLEUNITS>4 DO BEGIN
MYENTRYPRICE := IF(OPEN<MYENTRYPRICE-N ,OPEN ,MYENTRYPRICE-N ) ;
MYENTRYPRICE := FLOOR(MYENTRYPRICE/MINDIFF)*MINDIFF ;
BUYSHORT( _DEBUG,POSNUM, LIMITR, MYENTRYPRICE);
TURTLEUNITS := TURTLEUNITS+1 ;
BUYORDERTHISBAR := 1;
END //IF
//建立空头离场条件
SHORTX1 := H > T10HI ;
IF SHORTX1 AND BUYORDERTHISBAR=0 THEN BEGIN
MYEXITPRICE := IF(OPEN>T10HI+MINDIFF ,OPEN ,T10HI+MINDIFF ) ;
SELLSHORT( _DEBUG,0,LIMITR,MYEXITPRICE);
POSITION := 0 ;
TURTLEUNITS := 0 ;
END
//建立空头止损条件
SHORTX2 := HIGH > MYENTRYPRICE + X*N ;
IF SHORTX2 AND POSITION = -1 AND BUYORDERTHISBAR=0 THEN BEGIN
MYEXITPRICE := IF(OPEN>MYENTRYPRICE+N ,OPEN ,MYENTRYPRICE+N ) ;
MYEXITPRICE := CEILING(MYEXITPRICE/MINDIFF)*MINDIFF ;
SELLSHORT( _DEBUG,0,LIMITR,MYEXITPRICE);
POSITION := 0 ;
TURTLEUNITS := 0 ;
END
END //IF
//显示账户状态
CONTINUELINE@ 资产:ASSET,LINETHICK0;
可用现金:CASH(0),LINETHICK0;
POS:HOLDING,LINETHICK0;
交易次数:TOTALDAYTRADE, LINETHICK0 ;
IF _DEBUGOUT>0 THEN BEGIN
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'BARPOS=%.0F\' ,BARPOS,NT ) ;
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'T20HI=%.2F\' ,T20HI ,NT) ;
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'N=%.2F\' ,N ,NT) ;
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'CLOSE=%.2F\' ,C ,NT) ;
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'POSITION=%.0F\' ,POSITION,NT ) ;
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'TURTLEUNITS=%.0F\' ,TURTLEUNITS,NT ) ;
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'MYENTRYPRICE=%.0F\' ,MYENTRYPRICE ,NT) ;
DEBUGFILE2(\'C:\\DEBUGFILE.TXT\',\'MYEXITPRICE=%.0F\' ,MYEXITPRICE ,NT) ;
END //IF
当前持仓:HOLDING,COLORGRAY,LINETHICK0;
当前资产:ASSET,NOAXIS,COLORGRAY;
-- 发布时间：2015/3/2 9:46:49
--
143行， LONGX2 := (LOW< MYENTRYPRICE -X*N)
MYENTRYPRICE -X*N单独输出是正确的，不知道为什么在一起就错误了。x=2 m=54.45,
止损应该是4937-2*54.45=4828
-- 发布时间：2015/3/2 9:47:05
--
请把错误详细的描述一下，
-- 发布时间：2015/3/2 10:13:05
--
就是2011/05/06的平多，价格不对，应该是4828才平的，而不是一开盘就平4851
-- 发布时间：2015/3/2 10:33:32
--
你纠结的地方错了,你纠结的地方是对的
问题是：
你的平仓价位是
MYEXITPRICE := IF(OPEN<MYENTRYPRICE-N ,OPEN ,MYENTRYPRICE-N ) ;
MYEXITPRICE := FLOOR(MYEXITPRICE/MINDIFF)*MINDIFF ;
在当根k线上，OPEN<MYENTRYPRICE-N 的条件是满足的，所以myexitprice的值是open也就是4851
-- 发布时间：2015/3/2 10:50:07
--
谢谢，你一针见血的指出了问题所在。