- 金字塔客服中心 - 专业程序化交易软件提供商 (http://weistock.com/bbs/index.asp)
-- 公式模型编写问题提交 (http://weistock.com/bbs/list.asp?boardid=4)
---- 自编日内交易模块在两台电脑开现不同的情况 (http://weistock.com/bbs/dispbbs.asp?boardid=4&id=141724)
-- 发布时间：2016/10/25 8:46:38
-- 自编日内交易模块在两台电脑开现不同的情况
不知什么原因？
1. 自编日内交易模块在两台电脑开现不同的情况：一台有交易信号，另一台没有交易信号。
2·有交易信号这台电脑也出现不同的情况：有的品种有信号，又有的品种没信号（如沪铜等）
-- 发布时间：2016/10/25 9:17:07
--
http://www.weistock.com/bbs/dispbbs.asp?boardid=16&Id=57075
类似于这里的问题21，都是信号不一样的问题
-- 发布时间：2016/10/25 10:54:46
--
超级日内组合系统和自编日内交易模块一样在我另台电脑也没有交易信号，不管我反复册除重装软件都不显示交易信号，但测评有交易结果。是安装有误，还是旧软件残留有什么未清除？
21.超级日内组合系统
//中间变量
INPUT:SS(1,1,100,1),K1(0.3,0.1,1,0.1),K2(0.6,0.1,1,0.1),BOCP(0.25,0,1,0.01),FBOCP(0.25,0,1,0.01);
VARIABLE:开多次数=0,开空次数=0,趋买市=0,趋卖市=0,多头止损价=0,空头止损价=0;
CYC:=BARSLAST(DATE>REF(DATE,1))+1;
昨开:=CALLSTOCK(STKLABEL,VTOPEN,6,-1);
昨收:=CALLSTOCK(STKLABEL,VTCLOSE,6,-1);
昨昨收:=CALLSTOCK(STKLABEL,VTCLOSE,6,-2);//昨天的前一天的收盘价，暂称为昨昨收
昨低:=CALLSTOCK(STKLABEL,VTLOW,6,-1);
昨高:=CALLSTOCK(STKLABEL,VTHIGH,6,-1);
今高:=IF(CYC=1,HIGH,REF(HHV(HIGH,CYC),1));
今低:=IF(CYC=1,LOW,REF(LLV(LOW,CYC),1));
今开:=IF(CYC=1,OPEN,REF(OPEN,CYC-1));
10日平均波幅:=ref(MA(CALLSTOCK(STKLABEL,VTHIGH,6,0)-CALLSTOCK(STKLABEL,VTLOW,6,0),10),1);//AVERAGERANGE
10日平均开收盘区间:=ref(MA(ABS(CALLSTOCK(STKLABEL,VTopen,6,0)-CALLSTOCK(STKLABEL,VTclose,6,0)),10),1);//AVERAGEOCRANGE
开关:=ABS(昨开-昨收)<0.85*10日平均开收盘区间;//CANTRADE
3周期最高价:=REF(HHV(HIGH,3),1);
3周期最低价:=REF(LLV(LOW,3),1);
多头突破确认价:=昨高+BOCP*10日平均波幅;//LONGBREAKPT
空头突破确认价:=昨低-BOCP*10日平均波幅;//SHORTBREAKPT
多翻空确认价:=昨低+FBOCP*10日平均波幅;//LONGFBOPOINT
空翻多确认价:=昨高-FBOCP*10日平均波幅;//SHORTFBOPOINT
手数:=SS;
开仓历时:=ENTERBARS+1;
//交易条件
IF 昨收<=昨昨收 THEN BEGIN//昨日收盘价小于等于昨昨收为趋买市（BUYEASIERDAY)
趋买市:=1;
趋买市开多价:今开+K1*10日平均波幅;//BUYBOPT
趋买市开空价:今开-K2*10日平均波幅;//SELLBOPOINT
END
IF 昨收>昨昨收 THEN BEGIN//昨日收盘价大于昨昨收为趋买市（SELLEASIERDAY)
趋卖市:=1;
趋卖市开多价:今开+K2*10日平均波幅;//BUYBOPT
趋卖市开空价:今开-K1*10日平均波幅;//SELLBOPOINT
END
//交易系统
//突破
IF TIME>=094500 AND TIME<143000 AND 开关=1 THEN BEGIN
{趋买市}
IF 趋买市=1 AND 开多次数=0 THEN BEGIN
趋买市开多:BUY(C>=趋买市开多价 AND HOLDING=0,手数,MARKET);
多头止损价:=MIN(ENTERPRICE-0.25*10日平均波幅,ENTERPRICE-3);//这个策略用于股指，多头常规止损价为 开仓价减25%的10日平均波幅和3个大点的较小值。
开多次数:=1;
END
IF 趋买市=1 AND 开空次数=0 THEN BEGIN
趋买市开空:BUYSHORT(CLOSE<=趋买市开空价 AND HOLDING=0,手数,MARKET);
空头止损价:=Max(ENTERPRICE+0.25*10日平均波幅,ENTERPRICE+3);//这个策略用于股指，空头常规止损价为 开仓价加25%的10日平均波幅和3个大点的较小值。
开空次数:=1;
END
{趋卖市}
IF 趋卖市=1 AND 开多次数=0 THEN BEGIN
趋卖市开多:BUY(CLOSE>趋卖市开多价 AND HOLDING=0,手数,MARKET);
多头止损价:=MIN(ENTERPRICE-0.25*10日平均波幅,ENTERPRICE-3);
开多次数:=1;
END
IF 趋卖市=1 AND 开空次数=0 THEN BEGIN
趋卖市开空:BUYSHORT(CLOSE<趋卖市开空价 AND HOLDING=0,手数,MARKET);
空头止损价:=Max(ENTERPRICE+0.25*10日平均波幅,ENTERPRICE+3);
开空次数:=1;
END
END
//突破失败
{多头突破失败情况1:价格曾经高于多头突破确认价，最新价又回落至空翻多确认价}
IF 今高>多头突破确认价 AND C<多翻空确认价 AND TIME<143000 AND 开空次数=0 AND HOLDING>=0 THEN BEGIN
多头止损1:SELL(1,手数,MARKET);
多翻空1:BUYSHORT(1,手数,MARKET);
开空次数:=1;
END
{多头突破失败情况2:突破入场后,行情反转。止损的同时我们反手开空，但前提是时间在中午11:30之前，且多头进场在至少4根K之前。瞬间止损我们不允许反转，因为这往往是市场的膝跳反射}
IF HOLDING>=0 AND TIME<143000 AND 开空次数=0 THEN BEGIN
IF C<=多头止损价 THEN BEGIN
多头止损2:SELL(1,手数,MARKET);
IF TIME<=110000 AND 开仓历时>=4 THEN BEGIN
多翻空2:BUYSHORT(1,手数,MARKET);
空头止损价:=MIN(ENTERPRICE+0.15*10日平均波幅,ENTERPRICE+3);//多翻空止损价为开仓价加15%的10日平均波幅和3个大点的较小值。
开空次数:=1;
END
END
END
{空头突破失败情况1:价格曾经低于空头突破确认价，最新价又上涨至空翻多确认价}
IF 今低<空头突破确认价 AND C>空翻多确认价 AND TIME<143000 AND 开多次数=0 AND HOLDING<=0 THEN BEGIN
空头止损1:SELLSHORT(1,手数,MARKET);
空翻多1:BUY(1,手数,MARKET);
开多次数:=1;
END
{空头突破失败情况2:突破入场后,行情反转。止损的同时我们反手开多，但前提是时间在中午11:30之前，且空头进场在至少4根K之前。瞬间止损我们不允许反转，因为这往往是市场的膝跳反射}
IF HOLDING<0 AND TIME<143000 AND 开多次数=0 THEN BEGIN
IF C>=空头止损价 THEN BEGIN
空头止损2:SELLSHORT(1,手数,MARKET);
IF TIME<=110000 AND 开仓历时>=4 THEN BEGIN
空翻多2:BUY(1,手数,MARKET);
多头止损价:=MIN(ENTERPRICE-0.15*10日平均波幅,ENTERPRICE-3);//多翻空止损价为开仓价加15%的10日平均波幅和3个大点的较小值。
开多次数:=1;
END
END
END
//止损
IF HOLDING>0 AND C<多头止损价 AND TIME<151000 THEN 常规多头止损:SELL(1,手数,MARKET);
IF HOLDING<0 AND C>空头止损价 AND TIME<151000 THEN 常规空头止损:SELLSHORT(1,手数,MARKET);
//止损价调整
{若持多单，而5分钟K高点超过了开仓价+50%10日平均波幅，止损调整为保本型 }
IF 今高>ENTERPRICE+0.5*10日平均波幅 THEN 多头止损价:=ENTERPRICE+2*MINDIFF;
IF 今低<ENTERPRICE-0.5*10日平均波幅 THEN 空头止损价:=ENTERPRICE-2*MINDIFF;
{若时间处于14:30以后，多头跟踪止损为过去3个5分钟的最高低点与多空头止损价中的较大值}
IF TIME>=143000 THEN BEGIN
多头止损价:=MAX(多头止损价,3周期最低价);
空头止损价:=MIN(空头止损价,3周期最高价);
END
//日内平仓
IF TIME>=151000 THEN BEGIN
收盘平多:SELL(1,手数,MARKET);
收盘平空:SELLSHORT(1,手数,MARKET);
趋卖市:=0;
趋买市:=0;
开多次数:=0;
开空次数:=0;
多头止损价:=0;
空头止损价:=0;
END
-- 发布时间：2016/10/25 11:02:23
--
根据上面链接里面的问题，你要检查一下数据，费率 等问题
-- 发布时间：2016/10/25 11:12:02
--
我查不出是什么回题，其他交易模块没问题，辛苦你加载一下是什么原因？
-- 发布时间：2016/10/25 11:24:10
--
首先这个用在商品期货上要用北京时间时区
其次数据，这个很重要，你要有日线数据，要有当前数据，当前k线一定要显示很多的数据，只要是20天的，然后日线数据也要有20天的
最后并不是所有行情都适用这个策略的，有的品种因为行情因为数据不出信号是正常的
-- 发布时间：2016/10/26 11:15:47
--
拜托了！试了几十次没办法解决，在同台电脑另装金字塔软件也存在系统自带交易系统没有信号（有：12.R-Breaker【日内策略】，13.菲阿里四价，16.Dual Thrust，21.超级日内组合系统）；而原来安装的金字塔软件都有交易信号。恳请解决！！
-- 发布时间：2016/10/26 11:28:38
--
上面的几条都是解决你问题的思路，用户不停重装但是不查上面的问题，是没用的
-- 发布时间：2016/10/26 12:43:01
--
1.两种时间都改了,软件上改北京时区或交易系统改为金字塔时区.
2.品种因为行情问题不存在，在原安装软件上有交易信号.
3.数据从 工具_数据补充_最近30天的数据;
请一问: 21.超级日内组合系统在你哪儿有没交易信号? 难道原安装软件有问题或更改什么,以至于新安装都不行?
-- 发布时间：2016/10/26 13:18:45
--
有信号，但是不多，所以你要多补充k线数据，你新的软件不补充数据，是没有的。数据不会自动跑进你的电脑里
此主题相关图片如下：1.png